kde-plasma/plasma-firewall: 5.23.2 version bump

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 65 insertions, 0 deletions

diff --git a/kde-plasma/plasma-firewall/Manifest b/kde-plasma/plasma-firewall/Manifest
index 8e7454141ff0..d0bcfa9b876a 100644
--- a/kde-plasma/plasma-firewall/Manifest
+++ b/kde-plasma/plasma-firewall/Manifest
@@ -1,2 +1,3 @@
 DIST plasma-firewall-5.22.5.tar.xz 339372 BLAKE2B 332a7fd2be63429c452f43371b2875f8838e05b107a6c3472974c5db123eef9e415ec70601cb830a743d77422639225e01611e52c07a2b3fe079572278e2f638 SHA512 cc81884550b5c73061f5a1df24c0b32e5fff234a51e56153e95a9e4b0e23c305a555c2deff69633b9cd21dff7bfbcf5d9fcbd5ab3605d4ffa87be57514a91901
 DIST plasma-firewall-5.23.1.tar.xz 343896 BLAKE2B 1d4b4a963cad1e83227141867998fefe11b4d1cff425e217400acfe4c0e056db9408bae984f82d602962cc0cd7c26c8019e9b5f3b751f397e3396bb728d95b92 SHA512 fd8955699c02e902a97b9b3cdda583af0a30676d6dd281877ee64eba6ae626a600ee9eb24de2c32163a9cf205b5ba94b851d7990cf6b822809ee55a2a982cddb
+DIST plasma-firewall-5.23.2.tar.xz 343908 BLAKE2B b88677569962203df015d20b56eccc47b14f08d7f58cecbbc4639287addb7a2c212ff6d887363cfb7f490db003ccd7254a9c095caa33be5a679c79d25015bd20 SHA512 6c6ab2d51d4a23290ce909a960451eb4cd45b2d5ef25f590e44182edf7b27c4c02961606a59cad65231a451507018b1740d671672ff1e54d53a859141ced158b
diff --git a/kde-plasma/plasma-firewall/plasma-firewall-5.23.2.ebuild b/kde-plasma/plasma-firewall/plasma-firewall-5.23.2.ebuild
new file mode 100644
index 000000000000..dfd7cff04540
--- /dev/null
+++ b/kde-plasma/plasma-firewall/plasma-firewall-5.23.2.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+KFMIN=5.86.0
+QTMIN=5.15.2
+inherit ecm kde.org python-single-r1
+
+DESCRIPTION="Plasma frontend for Firewalld or UFW"
+HOMEPAGE="https://invent.kde.org/network/plasma-firewall"
+
+LICENSE="GPL-2+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="firewalld +ufw"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE} || ( firewalld ufw )"
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtx11extras-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/kauth-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/plasma-${KFMIN}:5
+"
+RDEPEND="${DEPEND}
+	${PYTHON_DEPS}
+	firewalld? ( net-firewall/firewalld )
+	ufw? ( net-firewall/ufw )
+"
+
+src_prepare() {
+	ecm_src_prepare
+	# this kind of cmake magic doesn't work for us at all.
+	sed -e "1 s:^.*$:\#\!/usr/bin/env ${EPYTHON}:" \
+		-i kcm/backends/ufw/helper/kcm_ufw_helper.py.cmake || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_FIREWALLD_BACKEND=$(usex firewalld)
+		-DBUILD_UFW_BACKEND=$(usex ufw)
+	)
+	ecm_src_configure
+}
+
+pkg_postinst () {
+	ecm_pkg_postinst
+
+	if ! has_version sys-apps/systemd; then
+		ewarn "${PN} is not functional without sys-apps/systemd at this point."
+		ewarn "See also: https://bugs.gentoo.org/778527"
+	fi
+}