media-gfx/opencsg: new version 1.4.0 to fix two bugs.

This fixes a version bump request from one of our users, and also a
build failure. Version 1.3.2 tried to link with QtGui, even though
that wasn't a declared dependency, causing the build to fail when it
was missing. The new v1.4.0 doesn't seem to have that problem, so the
build failure should be gone.

In the process, the ebuild was updated to use EAPI=6 and
qmake-utils.eclass.

Gentoo-Bug: 514210
Gentoo-Bug: 515124

Package-Manager: portage-2.2.28

1 files changed, 45 insertions, 0 deletions

diff --git a/media-gfx/opencsg/opencsg-1.4.0.ebuild b/media-gfx/opencsg/opencsg-1.4.0.ebuild
new file mode 100644
index 000000000000..f9eb9d7bd048
--- /dev/null
+++ b/media-gfx/opencsg/opencsg-1.4.0.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit qmake-utils
+
+MY_P="OpenCSG-${PV}"
+DESCRIPTION="The Constructive Solid Geometry rendering library"
+HOMEPAGE="http://www.opencsg.org"
+SRC_URI="http://www.opencsg.org/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+COMMON_DEPEND="media-libs/glew:0 dev-qt/qtcore:4"
+DEPEND="${COMMON_DEPEND}"
+RDEPEND="${COMMON_DEPEND}"
+
+S="${WORKDIR}/${MY_P}/src"
+
+src_prepare() {
+	default
+
+	# removes duplicated headers
+	rm -r ../glew || die "failed to remove bundled glew"
+
+	sed -i -e 's:^INSTALLDIR.*:INSTALLDIR = /usr:' src.pro \
+		|| die 'failed to fix INSTALLDIR in src.pro'
+
+	sed -i -e "s:^target.path.*:target.path = \$\$INSTALLDIR/$(get_libdir):" \
+		src.pro \
+		|| die 'failed to fix target.path in src.pro'
+}
+
+src_configure() {
+	eqmake4 src.pro
+}
+
+src_install() {
+	emake INSTALL_ROOT="${D}" install
+}