media-gfx/wkhtmltopdf: 0.12.5 version bump

Closes: https://bugs.gentoo.org/665744
Package-Manager: Portage-2.3.49, Repoman-2.3.10

1 files changed, 43 insertions, 0 deletions

diff --git a/media-gfx/wkhtmltopdf/wkhtmltopdf-0.12.5.ebuild b/media-gfx/wkhtmltopdf/wkhtmltopdf-0.12.5.ebuild
new file mode 100644
index 000000000000..3fb400e2f185
--- /dev/null
+++ b/media-gfx/wkhtmltopdf/wkhtmltopdf-0.12.5.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit qmake-utils
+
+DESCRIPTION="Convert html to pdf (and various image formats) using webkit"
+HOMEPAGE="https://wkhtmltopdf.org/ https://github.com/wkhtmltopdf/wkhtmltopdf/"
+SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="examples"
+
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5[ssl]
+	dev-qt/qtprintsupport:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwebkit:5[printsupport]
+	dev-qt/qtwidgets:5
+"
+DEPEND="${RDEPEND}
+	dev-qt/qtxmlpatterns:5
+"
+
+src_prepare() {
+	default
+	sed -i "s:\(INSTALLBASE/\)lib:\1$(get_libdir):" src/lib/lib.pro || die
+}
+
+src_configure() {
+	eqmake5 INSTALLBASE=/usr
+}
+
+src_install() {
+	emake INSTALL_ROOT="${D}" install
+	use examples && dodoc -r examples
+	einstalldocs
+}