proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 79 insertions, 0 deletions

diff --git a/media-gfx/zbar/zbar-0.10_p20121015.ebuild b/media-gfx/zbar/zbar-0.10_p20121015.ebuild
new file mode 100644
index 000000000000..7beedc913b7a
--- /dev/null
+++ b/media-gfx/zbar/zbar-0.10_p20121015.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit autotools eutils flag-o-matic python-single-r1
+
+DESCRIPTION="Library and tools for reading barcodes from images or video"
+HOMEPAGE="http://zbar.sourceforge.net/"
+SRC_URI="http://dev.gentoo.org/~xmw/zbar-0.10_p20121015.zip"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="gtk imagemagick jpeg python qt4 static-libs +threads v4l X xv"
+
+RDEPEND="sys-devel/gettext
+	gtk? ( dev-libs/glib:2 x11-libs/gtk+:2 )
+	imagemagick? (
+		|| ( media-gfx/imagemagick
+		media-gfx/graphicsmagick[imagemagick] ) )
+	jpeg? ( virtual/jpeg:0 )
+	python? ( ${PYTHON_DEPS}
+		gtk? ( >=dev-python/pygtk-2[${PYTHON_USEDEP}] ) )
+	qt4? ( dev-qt/qtcore:4 dev-qt/qtgui:4 )
+	X? ( x11-libs/libXext
+		xv? ( x11-libs/libXv ) )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_unpack() {
+	#vcs-snapshot doesn't work on .zip
+	default
+	mv * ${P} || die
+}
+
+src_prepare() {
+	#epatch "${FILESDIR}"/${P}-no-v4l1-check.patch
+	epatch "${FILESDIR}"/${PN}-0.10-errors.patch
+	epatch "${FILESDIR}"/${PN}-0.10-python-crash.patch
+
+	use python && python_fix_shebang examples/upcrpc.py test/*.py
+
+	sed -e '/AM_INIT_AUTOMAKE/s: -Werror : :' \
+		-e '/^AM_CFLAGS=/s: -Werror::' \
+		-i configure.ac || die
+	eautoreconf
+}
+
+src_configure() {
+	append-cppflags -DNDEBUG
+	econf \
+		$(use_with jpeg) \
+		$(use_with gtk) \
+		$(use_with imagemagick) \
+		$(use_with python) \
+		$(use_with qt4 qt) \
+		$(use_enable static-libs static) \
+		$(use_enable threads pthread) \
+		$(use_with X x) \
+		$(use_with xv xv) \
+		$(use_enable v4l video)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	dodoc HACKING NEWS README TODO
+	rm -r "${ED}"/usr/share/doc/${PN}
+	prune_libtool_files --all
+}