media-gfx/gnome-screenshot: Version bump to 41.0

Signed-off-by: Matt Turner <mattst88@gentoo.org>

2 files changed, 67 insertions, 0 deletions

diff --git a/media-gfx/gnome-screenshot/Manifest b/media-gfx/gnome-screenshot/Manifest
index 014aff96185d..05eb6d1d75bb 100644
--- a/media-gfx/gnome-screenshot/Manifest
+++ b/media-gfx/gnome-screenshot/Manifest
@@ -1 +1,2 @@
 DIST gnome-screenshot-40.0.tar.xz 358088 BLAKE2B cad407f471e953667946b741ed59fe210d7ba3d079f2db8101974e565a1d0bfaec0cb1b40791be0e183dd399a82db5f15bbbec741ef16b4b572b043fcaf8ea8e SHA512 0889d7701711f17de68f8a55f512b7764fed087b1b2f86b372d1a38ee956f05ca8c833ca16a1de2396b07c01de79204d988192036780f521b82733436d019cb0
+DIST gnome-screenshot-41.0.tar.xz 359500 BLAKE2B d3e44ab565815998327ddcbe80979acff3d690cfb0b7ae8f21910bafd21c9c7d3cd7af11e14b0522bb4d64ad2e27d5b6209c80208ea8fb03c465eb453ef8d47f SHA512 ab6c7e22cbca2739844707e59329ecd67901e04f968bd0b20a07dffff825e9772697ebf20a1ab2a920fa839ea40d0bd872d17db2b4cb7856a6f8ee4ec1426d19
diff --git a/media-gfx/gnome-screenshot/gnome-screenshot-41.0.ebuild b/media-gfx/gnome-screenshot/gnome-screenshot-41.0.ebuild
new file mode 100644
index 000000000000..2ae3882d508d
--- /dev/null
+++ b/media-gfx/gnome-screenshot/gnome-screenshot-41.0.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit gnome.org gnome2-utils meson readme.gentoo-r1 xdg
+
+DESCRIPTION="Screenshot utility for GNOME"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-screenshot"
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE="X"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+DEPEND="
+	X? (
+		x11-libs/libX11
+		x11-libs/libXext
+	)
+	>=dev-libs/glib-2.35.1:2[dbus]
+	>=x11-libs/gtk+-3.12.0:3
+	>=gui-libs/libhandy-1:1=
+"
+RDEPEND="${DEPEND}
+	>=gnome-base/gsettings-desktop-schemas-0.1.0
+"
+BDEPEND="
+	dev-libs/appstream-glib
+	dev-libs/libxml2:2
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	x11-base/xorg-proto
+"
+
+PATCHES=(
+	# Fix HiDPI handling in X11 fallback
+	# https://gitlab.gnome.org/GNOME/gnome-screenshot/-/issues/128
+	"${FILESDIR}"/${PN}-40.0-fix-hidpi.patch
+)
+
+DOC_CONTENTS="${P} saves screenshots in ~/Pictures/ and defaults to
+	non-interactive mode when launched from a terminal. If you want to choose
+	where to save the screenshot, run 'gnome-screenshot --interactive'"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature X x11)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+	readme.gentoo_print_elog
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}