media-libs/libavif: Bump to 0.10.1

Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Daniel Novomesky <dnovomesky@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/25005
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

3 files changed, 109 insertions, 4 deletions

diff --git a/media-libs/libavif/Manifest b/media-libs/libavif/Manifest
index 343db8559ca7..d5266f05d564 100644
--- a/media-libs/libavif/Manifest
+++ b/media-libs/libavif/Manifest
@@ -1 +1,2 @@
+DIST libavif-0.10.1.tar.gz 2085698 BLAKE2B 5be3f9adf7e0a5747e42c90ce2768eba90053c821805cc8e39915d6cbc4cd42554b1473118b41eb25010d20a2b5a3c141b9cbd6ff55c46abd79eb97cdee6b0e5 SHA512 2f6f248c56c983761149d3c201fc2a2ea5072a32516578a7fdb2c66e3cd22491540f400e23581f873b15454250eeec8d433924ae2c1de9371b7924a5d82bef6b
 DIST libavif-0.9.3.tar.gz 2000521 BLAKE2B b9dbaf01e58058a1ab9191081242a0f669b714d319075b6330963bc8ae31f576fb77b108de4745125eb42d39682e74a3174d062a029ccb765b3030f4092a96b8 SHA512 8e95666c784d1badc7e18d27a7c21cae3b8ef3b8da9a762eb8f7216d77fba29b9ca309c01d13bcf4890e03c6bc335ba4baf3f5877396bd0584be9ea60018daa7
diff --git a/media-libs/libavif/libavif-0.10.1.ebuild b/media-libs/libavif/libavif-0.10.1.ebuild
new file mode 100644
index 000000000000..0b126b8eea65
--- /dev/null
+++ b/media-libs/libavif/libavif-0.10.1.ebuild
@@ -0,0 +1,104 @@
+# Copyright 2020-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake-multilib gnome2-utils
+
+DESCRIPTION="Library for encoding and decoding .avif files"
+HOMEPAGE="https://github.com/AOMediaCodec/libavif"
+SRC_URI="https://github.com/AOMediaCodec/libavif/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD-2"
+# See bug #822336 re subslot
+SLOT="0/${PV}"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="+aom dav1d examples extras gdk-pixbuf rav1e svt-av1"
+
+REQUIRED_USE="|| ( aom dav1d )"
+
+DEPEND="media-libs/libpng[${MULTILIB_USEDEP}]
+	sys-libs/zlib[${MULTILIB_USEDEP}]
+	virtual/jpeg[${MULTILIB_USEDEP}]
+	aom? ( >=media-libs/libaom-3.3.0:=[${MULTILIB_USEDEP}] )
+	dav1d? ( >=media-libs/dav1d-1.0.0:=[${MULTILIB_USEDEP}] )
+	gdk-pixbuf? ( x11-libs/gdk-pixbuf:2[${MULTILIB_USEDEP}] )
+	rav1e? ( >=media-video/rav1e-0.5.1[capi] )
+	svt-av1? ( >=media-libs/svt-av1-0.9.1 )"
+RDEPEND="${DEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+multilib_src_configure() {
+	local mycmakeargs=(
+		-DBUILD_SHARED_LIBS=ON
+		-DAVIF_CODEC_AOM=$(usex aom ON OFF)
+		-DAVIF_CODEC_DAV1D=$(usex dav1d ON OFF)
+		-DAVIF_CODEC_LIBGAV1=OFF
+
+		# Use system libraries.
+		-DAVIF_LOCAL_ZLIBPNG=OFF
+		-DAVIF_LOCAL_JPEG=OFF
+
+		-DAVIF_BUILD_GDK_PIXBUF=$(usex gdk-pixbuf ON OFF)
+
+		-DAVIF_ENABLE_WERROR=OFF
+	)
+
+	if multilib_is_native_abi; then
+		mycmakeargs+=(
+			-DAVIF_CODEC_RAV1E=$(usex rav1e ON OFF)
+			-DAVIF_CODEC_SVT=$(usex svt-av1 ON OFF)
+
+			-DAVIF_BUILD_EXAMPLES=$(usex examples ON OFF)
+			-DAVIF_BUILD_APPS=$(usex extras ON OFF)
+			-DAVIF_BUILD_TESTS=$(usex extras ON OFF)
+		)
+	else
+		mycmakeargs+=(
+			-DAVIF_CODEC_RAV1E=OFF
+			-DAVIF_CODEC_SVT=OFF
+
+			-DAVIF_BUILD_EXAMPLES=OFF
+			-DAVIF_BUILD_APPS=OFF
+			-DAVIF_BUILD_TESTS=OFF
+		)
+
+		if ! use aom ; then
+			if use rav1e || use svt-av1 ; then
+				ewarn "libavif on ${MULTILIB_ABI_FLAG} will work in read-only mode."
+				ewarn "Support for rav1e and/or svt-av1 is is not available on ${MULTILIB_ABI_FLAG}"
+				ewarn "Enable aom flag for full support on ${MULTILIB_ABI_FLAG}"
+			fi
+		fi
+	fi
+
+	cmake_src_configure
+}
+
+pkg_preinst() {
+	if use gdk-pixbuf ; then
+		gnome2_gdk_pixbuf_savelist
+	fi
+}
+
+pkg_postinst() {
+	if ! use aom && ! use rav1e && ! use svt-av1 ; then
+		ewarn "No AV1 encoder is set,"
+		ewarn "libavif will work in read-only mode."
+		ewarn "Enable aom, rav1e or svt-av1 flag if you want to save .AVIF files."
+	fi
+
+	if use gdk-pixbuf ; then
+		# causes segfault if set, see bug 375615
+		unset __GL_NO_DSO_FINALIZER
+		multilib_foreach_abi gnome2_gdk_pixbuf_update
+	fi
+}
+
+pkg_postrm() {
+	if use gdk-pixbuf ; then
+		# causes segfault if set, see bug 375615
+		unset __GL_NO_DSO_FINALIZER
+		multilib_foreach_abi gnome2_gdk_pixbuf_update
+	fi
+}
diff --git a/media-libs/libavif/libavif-9999.ebuild b/media-libs/libavif/libavif-9999.ebuild
index 80ef7d093431..1caa84d6e040 100644
--- a/media-libs/libavif/libavif-9999.ebuild
+++ b/media-libs/libavif/libavif-9999.ebuild
@@ -21,11 +21,11 @@ REQUIRED_USE="|| ( aom dav1d )"
 DEPEND="media-libs/libpng[${MULTILIB_USEDEP}]
 	sys-libs/zlib[${MULTILIB_USEDEP}]
 	virtual/jpeg[${MULTILIB_USEDEP}]
-	aom? ( >=media-libs/libaom-3.1.2:=[${MULTILIB_USEDEP}] )
-	dav1d? ( media-libs/dav1d:=[${MULTILIB_USEDEP}] )
+	aom? ( >=media-libs/libaom-3.3.0:=[${MULTILIB_USEDEP}] )
+	dav1d? ( >=media-libs/dav1d-1.0.0:=[${MULTILIB_USEDEP}] )
 	gdk-pixbuf? ( x11-libs/gdk-pixbuf:2[${MULTILIB_USEDEP}] )
-	rav1e? ( media-video/rav1e[capi] )
-	svt-av1? ( >=media-libs/svt-av1-0.8.6 )"
+	rav1e? ( >=media-video/rav1e-0.5.1[capi] )
+	svt-av1? ( >=media-libs/svt-av1-0.9.1 )"
 RDEPEND="${DEPEND}"
 BDEPEND="virtual/pkgconfig"