media-libs/libfreehand: 0.1.2 version bump

Package-Manager: Portage-2.3.11, Repoman-2.3.3

1 files changed, 48 insertions, 0 deletions

diff --git a/media-libs/libfreehand/libfreehand-0.1.2.ebuild b/media-libs/libfreehand/libfreehand-0.1.2.ebuild
new file mode 100644
index 000000000000..3ce6e903de14
--- /dev/null
+++ b/media-libs/libfreehand/libfreehand-0.1.2.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+EGIT_REPO_URI="https://anongit.freedesktop.org/git/libreoffice/libfreehand.git"
+[[ ${PV} == 9999 ]] && inherit autotools git-r3
+
+DESCRIPTION="Library for import of FreeHand drawings"
+HOMEPAGE="https://wiki.documentfoundation.org/DLP/Libraries/libfreehand"
+[[ ${PV} == 9999 ]] || SRC_URI="https://dev-www.libreoffice.org/src/libfreehand/${P}.tar.xz"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+[[ ${PV} == 9999 ]] || \
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="doc static-libs"
+
+RDEPEND="
+	dev-libs/librevenge
+	sys-libs/zlib
+"
+DEPEND="${RDEPEND}
+	dev-libs/icu:=
+	dev-util/gperf
+	media-libs/lcms
+	sys-devel/libtool
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+"
+
+src_prepare() {
+	default
+	[[ -d m4 ]] || mkdir "m4"
+	[[ ${PV} == 9999 ]] && eautoreconf
+}
+
+src_configure() {
+	econf \
+		--disable-werror \
+		$(use_with doc docs) \
+		$(use_enable static-libs static)
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}