media-libs/libheif: add missing media-libs/libaom dep

Package-Manager: Portage-3.0.4, Repoman-3.0.1
Signed-off-by: Jakov Smolic <jakov.smolic@sartura.hr>
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

1 files changed, 63 insertions, 0 deletions

diff --git a/media-libs/libheif/libheif-1.7.0-r2.ebuild b/media-libs/libheif/libheif-1.7.0-r2.ebuild
new file mode 100644
index 000000000000..e54b807b2dfa
--- /dev/null
+++ b/media-libs/libheif/libheif-1.7.0-r2.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools xdg multilib-minimal
+
+if [[ ${PV} == "9999" ]] ; then
+	EGIT_REPO_URI="https://github.com/strukturag/${PN}.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/strukturag/${PN}/releases/download/v${PV}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+fi
+
+DESCRIPTION="ISO/IEC 23008-12:2017 HEIF file format decoder and encoder"
+HOMEPAGE="https://github.com/strukturag/libheif"
+
+LICENSE="GPL-3"
+SLOT="0/1.7"
+IUSE="gdk-pixbuf go static-libs test +threads"
+RESTRICT="!test? ( test )"
+
+BDEPEND="test? ( dev-lang/go )"
+DEPEND="
+	>=media-libs/libaom-2.0.0:=[${MULTILIB_USEDEP}]
+	media-libs/libde265:=[${MULTILIB_USEDEP}]
+	media-libs/libpng:0=[${MULTILIB_USEDEP}]
+	media-libs/x265:=[${MULTILIB_USEDEP}]
+	sys-libs/zlib:=[${MULTILIB_USEDEP}]
+	virtual/jpeg:0=[${MULTILIB_USEDEP}]
+	gdk-pixbuf? ( x11-libs/gdk-pixbuf )
+	go? ( dev-lang/go )
+"
+RDEPEND="${DEPEND}"
+PATCHES=(
+	"${FILESDIR}"/${P}-aom.patch
+)
+
+src_prepare() {
+	default
+
+	sed -i -e 's:-Werror::' configure.ac || die
+
+	eautoreconf
+
+	# prevent "stat heif-test.go: no such file or directory"
+	multilib_copy_sources
+}
+
+multilib_src_configure() {
+	local econf_args=(
+		$(multilib_is_native_abi && use_enable go || echo --disable-go)
+		$(use_enable gdk-pixbuf)
+		$(use_enable static-libs static)
+		$(use_enable threads multithreading)
+	)
+	ECONF_SOURCE="${S}" econf "${econf_args[@]}"
+}
+
+multilib_src_install_all() {
+	find "${ED}" -name '*.la' -delete || die
+}