media-libs/mutagen: version bump to 1.42.0

Signed-off-by: Tim Harder <radhermit@gentoo.org>

1 files changed, 42 insertions, 0 deletions

diff --git a/media-libs/mutagen/mutagen-1.42.0.ebuild b/media-libs/mutagen/mutagen-1.42.0.ebuild
new file mode 100644
index 000000000000..e450254a80cf
--- /dev/null
+++ b/media-libs/mutagen/mutagen-1.42.0.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6,3_7} )
+
+inherit distutils-r1
+
+DESCRIPTION="Audio metadata tag reader and writer implemented in pure Python"
+HOMEPAGE="https://github.com/quodlibet/mutagen https://pypi.org/project/mutagen/"
+SRC_URI="https://github.com/quodlibet/mutagen/releases/download/release-${PV}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc test"
+
+# TODO: Missing support for >=dev-python/eyeD3-0.7 API
+# test? ( >=dev-python/eyeD3-0.7 )
+RDEPEND="dev-python/setuptools[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? (
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+	)
+"
+
+python_compile_all() {
+	use doc && emake -C docs
+}
+
+python_test() {
+	esetup.py test --no-quality
+}
+
+python_install_all() {
+	local DOCS=( NEWS README.rst )
+	use doc && local HTML_DOCS=( docs/_build/. )
+	distutils-r1_python_install_all
+}