media-libs/openimageio: Add USE dicom

Fixes automagic dependency.

Closes: https://bugs.gentoo.org/675598
Package-Manager: Portage-2.3.69, Repoman-2.3.16
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

1 files changed, 118 insertions, 0 deletions

diff --git a/media-libs/openimageio/openimageio-1.8.17-r1.ebuild b/media-libs/openimageio/openimageio-1.8.17-r1.ebuild
new file mode 100644
index 000000000000..177b41bd78c8
--- /dev/null
+++ b/media-libs/openimageio/openimageio-1.8.17-r1.ebuild
@@ -0,0 +1,118 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{5,6} )
+inherit cmake-utils python-single-r1
+
+DESCRIPTION="A library for reading and writing images"
+HOMEPAGE="https://sites.google.com/site/openimageio/ https://github.com/OpenImageIO"
+SRC_URI="https://github.com/OpenImageIO/oiio/archive/Release-${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+
+X86_CPU_FEATURES=(
+	sse2:sse2 sse3:sse3 ssse3:ssse3 sse4_1:sse4.1 sse4_2:sse4.2
+	avx:avx avx2:avx2 avx512f:avx512f f16c:f16c
+)
+CPU_FEATURES=( ${X86_CPU_FEATURES[@]/#/cpu_flags_x86_} )
+
+IUSE="color-management dicom doc ffmpeg field3d gif jpeg2k libressl opencv opengl ptex python qt5 raw ssl +truetype ${CPU_FEATURES[@]%:*}"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RESTRICT="test" # bug 431412
+
+BDEPEND="
+	doc? ( app-doc/doxygen[latex] )
+"
+RDEPEND="
+	>=dev-libs/boost-1.62:=
+	dev-libs/pugixml:=
+	>=media-libs/ilmbase-2.2.0-r1:=
+	media-libs/libpng:0=
+	>=media-libs/libwebp-0.2.1:=
+	>=media-libs/openexr-2.2.0-r2:=
+	media-libs/tiff:0=
+	sys-libs/zlib:=
+	virtual/jpeg:0
+	color-management? ( media-libs/opencolorio:= )
+	dicom? ( sci-libs/dcmtk )
+	ffmpeg? ( media-video/ffmpeg:= )
+	field3d? ( media-libs/Field3D:= )
+	gif? ( media-libs/giflib:0= )
+	jpeg2k? ( >=media-libs/openjpeg-1.5:0= )
+	opencv? ( media-libs/opencv:= )
+	opengl? (
+		media-libs/glew:=
+		virtual/glu
+		virtual/opengl
+	)
+	ptex? ( media-libs/ptex:= )
+	python? (
+		${PYTHON_DEPS}
+		dev-libs/boost:=[python,${PYTHON_USEDEP}]
+	)
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtwidgets:5
+		opengl? ( dev-qt/qtopengl:5 )
+	)
+	raw? ( media-libs/libraw:= )
+	ssl? (
+		!libressl? ( dev-libs/openssl:0= )
+		libressl? ( dev-libs/libressl:0= )
+	)
+	truetype? ( media-libs/freetype:2= )
+"
+DEPEND="${RDEPEND}"
+
+DOCS=( CHANGES.md CREDITS.md README.md src/doc/${PN}.pdf )
+
+S="${WORKDIR}/oiio-Release-${PV}"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_configure() {
+	# Build with SIMD support
+	local cpufeature
+	local mysimd=()
+	for cpufeature in "${CPU_FEATURES[@]}"; do
+		use "${cpufeature%:*}" && mysimd+=("${cpufeature#*:}")
+	done
+
+	# If no CPU SIMDs were used, completely disable them
+	[[ -z ${mysimd} ]] && mysimd=("0")
+
+	local mycmakeargs=(
+		-DINSTALL_DOCS=$(usex doc)
+		-DOIIO_BUILD_TESTS=OFF # as they are RESTRICTed
+		-DSTOP_ON_WARNING=OFF
+		-DUSE_EXTERNAL_PUGIXML=ON
+		-DUSE_JPEGTURBO=ON
+		-DUSE_NUKE=NO # Missing in Gentoo
+		-DUSE_NUKE=OFF
+		-DUSE_OCIO=$(usex color-management)
+		-DUSE_DICOM=$(usex dicom)
+		-DUSE_FFMPEG=$(usex ffmpeg)
+		-DUSE_FIELD3D=$(usex field3d)
+		-DUSE_GIF=$(usex gif)
+		-DUSE_OPENJPEG=$(usex jpeg2k)
+		-DUSE_OPENCV=$(usex opencv)
+		-DUSE_OPENGL=$(usex opengl)
+		-DUSE_PTEX=$(usex ptex)
+		-DUSE_PYTHON=$(usex python)
+		-DUSE_QT=$(usex qt5)
+		-DUSE_LIBRAW=$(usex raw)
+		-DUSE_OPENSSL=$(usex ssl)
+		-DUSE_FREETYPE=$(usex truetype)
+		-DUSE_SIMD=$(local IFS=','; echo "${mysimd[*]}")
+	)
+
+	cmake-utils_src_configure
+}