media-libs/opensubdiv: Version bump to 3.3 and remove ati-drivers

* Fixed compile error about stray quotes
* Changed hardcoded paths to GNUInstallDirs which
  fixed multilib-strict check fail

Closes: https://bugs.gentoo.org/605958
Closes: https://bugs.gentoo.org/611844
Closes: https://github.com/gentoo/gentoo/pull/5751

1 files changed, 63 insertions, 0 deletions

diff --git a/media-libs/opensubdiv/opensubdiv-3.3.0.ebuild b/media-libs/opensubdiv/opensubdiv-3.3.0.ebuild
new file mode 100644
index 000000000000..b73f2a25deb5
--- /dev/null
+++ b/media-libs/opensubdiv/opensubdiv-3.3.0.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit cmake-utils toolchain-funcs versionator
+
+MY_PV="$(replace_all_version_separators '_')"
+DESCRIPTION="An Open-Source subdivision surface library"
+HOMEPAGE="http://graphics.pixar.com/opensubdiv/"
+SRC_URI="https://github.com/PixarAnimationStudios/OpenSubdiv/archive/v${MY_PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="ZLIB"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="cuda doc examples opencl openmp ptex tbb tutorials"
+
+RDEPEND="media-libs/glew:=
+	media-libs/glfw:=
+	cuda? ( dev-util/nvidia-cuda-toolkit:* )
+	ptex? ( media-libs/ptex )"
+
+DEPEND="${RDEPEND}
+	tbb? ( dev-cpp/tbb )
+	doc? ( 
+		dev-python/docutils
+		app-doc/doxygen
+	)"
+
+S="${WORKDIR}/OpenSubdiv-${MY_PV}"
+
+PATCHES=(
+	"${FILESDIR}/${P}-fix-quotes.patch"
+	"${FILESDIR}/${P}-use-gnuinstalldirs.patch"
+)
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DNO_MAYA=1
+		-DNO_CLEW=1
+		-DNO_DOC=$(usex !doc)
+		-DNO_TBB=$(usex !tbb)
+		-DNO_PTEX=$(usex !ptex)
+		-DNO_OMP=$(usex !openmp)
+		-DNO_OPENCL=$(usex !opencl)
+		-DNO_CUDA=$(usex !cuda)
+		-DNO_REGRESSION=1 # They don't work with certain settings
+		-DNO_EXAMPLES=$(usex !examples)
+		-DNO_TUTORIALS=$(usex !tutorials)
+		-DGLEW_LOCATION="${EPREFIX}/usr/$(get_libdir)"
+		-DGLFW_LOCATION="${EPREFIX}/usr/$(get_libdir)"
+		-DCMAKE_INSTALL_DOCDIR="share/doc/${PF}"
+	)
+
+	cmake-utils_src_configure
+}