media-libs/partio: New package

C++ (with python bindings) library for easily reading/writing/manipulating
common animation particle formats such as PDB, BGEO, PTC.

This is a new dependency for media-libs/osl.

Closes: https://github.com/gentoo/gentoo/pull/5752

1 files changed, 45 insertions, 0 deletions

diff --git a/media-libs/partio/partio-1.1.0_p20170829.ebuild b/media-libs/partio/partio-1.1.0_p20170829.ebuild
new file mode 100644
index 000000000000..f5e7281f95e4
--- /dev/null
+++ b/media-libs/partio/partio-1.1.0_p20170829.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+
+inherit cmake-utils vcs-snapshot python-single-r1
+
+DESCRIPTION="A library for particle IO and manipulation"
+HOMEPAGE="http://www.disneyanimation.com/technology/partio.html"
+
+MY_GIT_COMMIT="2774ef3958da46d9f8a4230ebda9e04b1aa8f4e5"
+SRC_URI="https://github.com/wdas/${PN}/archive/${MY_GIT_COMMIT}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	media-libs/freeglut
+	virtual/opengl
+	sys-libs/zlib:=
+"
+
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen[latex] )
+	dev-lang/swig:*
+"
+
+src_prepare() {
+	cmake-utils_src_prepare
+
+	sed -e '/ADD_SUBDIRECTORY (src\/tests)/d' -i CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_find_package doc Doxygen)
+		-DCMAKE_INSTALL_DOCDIR="share/doc/${PF}"
+	)
+
+	cmake-utils_src_configure
+}