media-libs/portaudio: respect AR setting, bug #720966

AC_PATH_PROG only accepts absolute paths.
AC_CHECK_PROG is a correct way to detect binary names.

Reported-by: Agostino Sarubbo
Closes: https://bugs.gentoo.org/720966
Package-Manager: Portage-2.3.100, Repoman-2.3.22
Signed-off-by: Sergei Trofimovich <slyfox@gentoo.org>

1 files changed, 72 insertions, 0 deletions

diff --git a/media-libs/portaudio/portaudio-19.06.00-r3.ebuild b/media-libs/portaudio/portaudio-19.06.00-r3.ebuild
new file mode 100644
index 000000000000..5664a73ea98f
--- /dev/null
+++ b/media-libs/portaudio/portaudio-19.06.00-r3.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit autotools multilib-minimal
+
+DESCRIPTION="A free, cross-platform, open-source, audio I/O library"
+HOMEPAGE="http://www.portaudio.com/"
+SRC_URI="http://www.portaudio.com/archives/pa_stable_v190600_20161030.tgz
+	https://sources.debian.org/data/main/p/portaudio19/19.6.0-1/debian/patches/audacity-portmixer.patch -> ${PN}-19.06.00-audacity-portmixer.patch"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="alsa +cxx debug doc jack oss static-libs"
+
+RDEPEND="alsa? ( >=media-libs/alsa-lib-1.0.27.2[${MULTILIB_USEDEP}] )
+	jack? ( virtual/jack[${MULTILIB_USEDEP}] )"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	doc? ( app-doc/doxygen )
+	virtual/pkgconfig
+"
+
+S="${WORKDIR}/${PN}"
+
+DOCS=( README.txt )
+
+PATCHES=(
+	"${DISTDIR}/${PN}-19.06.00-audacity-portmixer.patch"
+	"${FILESDIR}"/${PN}-19.06.00-AR.patch # bug #720966, trigger reconf
+)
+
+src_prepare() {
+	default
+
+	eautoconf
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		$(use_enable debug debug-output)
+		$(use_enable cxx)
+		$(use_enable static-libs static)
+		$(use_with alsa)
+		$(use_with jack)
+		$(use_with oss)
+	)
+
+	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+multilib_src_compile() {
+	# workaround parallel build issue
+	emake lib/libportaudio.la
+	emake
+}
+
+src_compile() {
+	multilib-minimal_src_compile
+
+	if use doc; then
+		doxygen -u Doxyfile || die
+		doxygen Doxyfile || die
+	fi
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	use doc && dodoc -r doc/html
+	find "${ED}" -name "*.la" -delete || die
+}