media-libs/qtav: New package

Initial ebuild by me.

Closes: https://bugs.gentoo.org/show_bug.cgi?id=613146
Package-Manager: Portage-2.3.8, Repoman-2.3.3

1 files changed, 60 insertions, 0 deletions

diff --git a/media-libs/qtav/qtav-1.12.0.ebuild b/media-libs/qtav/qtav-1.12.0.ebuild
new file mode 100644
index 000000000000..6437e6a61b12
--- /dev/null
+++ b/media-libs/qtav/qtav-1.12.0.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+MY_PN="QtAV"
+CAPI_HASH="b43aa93"
+inherit cmake-utils
+
+DESCRIPTION="Multimedia playback framework based on Qt + FFmpeg"
+HOMEPAGE="https://www.qtav.org"
+SRC_URI="https://github.com/wang-bin/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz
+https://dev.gentoo.org/~johu/distfiles/${P}-capi.h-${CAPI_HASH}.xz"
+
+LICENSE="GPL-3+ LGPL-2.1+"
+SLOT="0/1"
+KEYWORDS="~amd64"
+IUSE="gui libav opengl portaudio pulseaudio vaapi"
+REQUIRED_USE="gui? ( opengl )"
+
+DEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtdeclarative:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	gui? ( dev-qt/qtsql:5 )
+	libav? (
+		media-video/libav:=
+		x11-libs/libX11
+	)
+	!libav? ( media-video/ffmpeg:= )
+	opengl? ( dev-qt/qtopengl:5 )
+	portaudio? ( media-libs/portaudio )
+	pulseaudio? ( media-sound/pulseaudio )
+"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+PATCHES=( "${FILESDIR}/${P}-multilib.patch" )
+
+src_prepare() {
+	cmake-utils_src_prepare
+	cp "${WORKDIR}/${P}-capi.h-${CAPI_HASH}" contrib/capi/capi.h \
+		|| die "Failed to add missing header"
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_TESTS=OFF
+		-DBUILD_EXAMPLES=OFF
+		-DBUILD_PLAYERS=$(usex gui)
+		-DBUILD_QT5OPENGL=$(usex opengl)
+		-DHAVE_PORTAUDIO=$(usex portaudio)
+		-DHAVE_PULSE=$(usex pulseaudio)
+		-DHAVE_VAAPI=$(usex vaapi)
+	)
+
+	cmake-utils_src_configure
+}