proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 75 insertions, 0 deletions

diff --git a/media-libs/smpeg/smpeg-0.4.4-r10.ebuild b/media-libs/smpeg/smpeg-0.4.4-r10.ebuild
new file mode 100644
index 000000000000..b1f57cbbb5ad
--- /dev/null
+++ b/media-libs/smpeg/smpeg-0.4.4-r10.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit eutils toolchain-funcs autotools flag-o-matic multilib-minimal
+
+DESCRIPTION="SDL MPEG Player Library"
+HOMEPAGE="http://icculus.org/smpeg/"
+SRC_URI="ftp://ftp.lokigames.com/pub/open-source/smpeg/${P}.tar.gz
+	mirror://gentoo/${P}-gtkm4.patch.bz2"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="alpha amd64 arm hppa ia64 ~mips ppc ppc64 sh sparc x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~ia64-linux ~x86-linux ~x86-solaris"
+IUSE="X debug cpu_flags_x86_mmx opengl static-libs"
+
+RDEPEND="
+	abi_x86_32? (
+		!app-emulation/emul-linux-x86-sdl[-abi_x86_32(-)]
+		!<=app-emulation/emul-linux-x86-sdl-20140406
+	)
+	>=media-libs/libsdl-1.2.15-r4[${MULTILIB_USEDEP}]
+	opengl? (
+		>=virtual/glu-9.0-r1[${MULTILIB_USEDEP}]
+		>=virtual/opengl-7.0-r1[${MULTILIB_USEDEP}]
+	)
+	X? (
+		>=x11-libs/libXext-1.3.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libXi-1.7.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
+	)"
+DEPEND="${RDEPEND}"
+
+DOCS=( CHANGES README README.SDL_mixer TODO )
+
+src_prepare() {
+	epatch "${FILESDIR}"/${P}-m4.patch \
+		"${FILESDIR}"/${P}-gnu-stack.patch \
+		"${FILESDIR}"/${P}-config.patch \
+		"${FILESDIR}"/${P}-PIC.patch \
+		"${FILESDIR}"/${P}-gcc41.patch \
+		"${FILESDIR}"/${P}-flags.patch \
+		"${FILESDIR}"/${P}-automake.patch \
+		"${FILESDIR}"/${P}-mmx.patch \
+		"${FILESDIR}"/${P}-malloc.patch \
+		"${FILESDIR}"/${P}-format.patch \
+		"${FILESDIR}"/${P}-missing-init.patch
+
+	cd "${WORKDIR}"
+	epatch "${DISTDIR}"/${P}-gtkm4.patch.bz2
+	rm "${S}/acinclude.m4"
+
+	cd "${S}"
+	AT_M4DIR="${S}/m4" eautoreconf
+}
+
+multilib_src_configure() {
+	[[ ${CHOST} == *-solaris* ]] && append-libs -lnsl -lsocket
+
+	# the debug option is bogus ... all it does is add extra
+	# optimizations if you pass --disable-debug
+	ECONF_SOURCE="${S}" econf \
+		--enable-debug \
+		--disable-gtk-player \
+		$(use_enable static-libs static) \
+		$(use_enable debug assertions) \
+		$(use_with X x) \
+		$(use_enable opengl opengl-player) \
+		$(use_enable cpu_flags_x86_mmx mmx)
+}
+
+multilib_src_install_all() {
+	use static-libs || prune_libtool_files
+}