media-libs/vulkan-layers: Bump to 1.1.125

Package-Manager: Portage-2.3.78, Repoman-2.3.17
Signed-off-by: Nick Sarnie <sarnex@gentoo.org>

1 files changed, 48 insertions, 0 deletions

diff --git a/media-libs/vulkan-layers/vulkan-layers-1.1.125.ebuild b/media-libs/vulkan-layers/vulkan-layers-1.1.125.ebuild
new file mode 100644
index 000000000000..468b7bd532a8
--- /dev/null
+++ b/media-libs/vulkan-layers/vulkan-layers-1.1.125.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{5,6,7} )
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/KhronosGroup/Vulkan-ValidationLayers.git"
+	EGIT_SUBMODULES=()
+	inherit git-r3
+else
+	EGIT_COMMIT="237d818e81fbffa073d29d94f53a2cbac4f25b9f"
+	KEYWORDS="~amd64 ~x86"
+	SRC_URI="https://github.com/KhronosGroup/Vulkan-ValidationLayers/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}/Vulkan-ValidationLayers-${EGIT_COMMIT}"
+fi
+
+inherit python-any-r1 cmake-multilib
+
+DESCRIPTION="Vulkan Validation Layers"
+HOMEPAGE="https://github.com/KhronosGroup/Vulkan-ValidationLayers"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="X wayland"
+
+DEPEND="${PYTHON_DEPS}
+		>=dev-util/glslang-7.11.3114_pre20190415:=[${MULTILIB_USEDEP}]
+		>=dev-util/spirv-tools-2019.1-r1:=[${MULTILIB_USEDEP}]
+		>=dev-util/vulkan-headers-1.1.125
+		wayland? ( dev-libs/wayland:=[${MULTILIB_USEDEP}] )
+		X? (
+		   x11-libs/libX11:=[${MULTILIB_USEDEP}]
+		   x11-libs/libXrandr:=[${MULTILIB_USEDEP}]
+		   )"
+
+multilib_src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_SKIP_RPATH=True
+		-DBUILD_WSI_WAYLAND_SUPPORT=$(usex wayland)
+		-DBUILD_WSI_XCB_SUPPORT=$(usex X)
+		-DBUILD_WSI_XLIB_SUPPORT=$(usex X)
+		-DBUILD_TESTS=False
+		-DGLSLANG_INSTALL_DIR="/usr"
+		-DCMAKE_INSTALL_INCLUDEDIR="/usr/include/vulkan/"
+	)
+	cmake-utils_src_configure
+}