media-libs/waffle: Version bump to 1.7.1

Signed-off-by: Matt Turner <mattst88@gentoo.org>

3 files changed, 69 insertions, 2 deletions

diff --git a/media-libs/waffle/Manifest b/media-libs/waffle/Manifest
index fccd4b6aa37e..6a01e0c524cc 100644
--- a/media-libs/waffle/Manifest
+++ b/media-libs/waffle/Manifest
@@ -1 +1,2 @@
 DIST waffle-v1.7.0.tar.bz2 302120 BLAKE2B 8ebfc78182ff86447d88d92edd6452dae28c1515de5f9639c402203bfb5a135bc493040941420161690a4812a202552266bceb89eee948d0c7aeae55d5b8d3d5 SHA512 ee7b8419e309387fa6d610174ba5dddda97525cef41c9600772b902eddfc4570e940437596d7fb50ee9dc2f5945e723236b61463975d2b9cc0faa150696d24c2
+DIST waffle-v1.7.1.tar.bz2 305830 BLAKE2B 8be098fa957f3d9cc84a72920e58fcee9ca4ab0b23a6d93b6cc7dfea17501448ff44a41c42f4c06ff81ef26c0041258b8709bcaf8abb4a593e8b3ac21e2085cd SHA512 e2ce6092c3088d0c4e85581700096954ab4f644e758b8639d2e9fa91771d2d964cd028361d346c9ae9c4ef185e6fc4c59acdee4480ee6ea6436f0d4bd61581a5
diff --git a/media-libs/waffle/waffle-1.7.1.ebuild b/media-libs/waffle/waffle-1.7.1.ebuild
new file mode 100644
index 000000000000..968c882955b5
--- /dev/null
+++ b/media-libs/waffle/waffle-1.7.1.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+if [[ ${PV} = *9999* ]]; then
+	EGIT_REPO_URI="https://gitlab.freedesktop.org/mesa/${PN}"
+	GIT_ECLASS="git-r3"
+else
+	SRC_URI="https://gitlab.freedesktop.org/mesa/${PN}/-/archive/v${PV}/${PN}-v${PV}.tar.bz2"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+	S="${WORKDIR}"/${PN}-v${PV}
+fi
+inherit meson-multilib multilib ${GIT_ECLASS}
+
+DESCRIPTION="Library that allows selection of GL API and of window system at runtime"
+HOMEPAGE="http://www.waffle-gl.org/ https://gitlab.freedesktop.org/mesa/waffle"
+
+LICENSE="BSD-2"
+SLOT="0"
+IUSE="doc +egl +gbm wayland X"
+RESTRICT="test" # gl_basic tests don't work when run from portage
+
+RDEPEND="
+	>=media-libs/mesa-9.1.6[egl(+)?,gbm(+)?,${MULTILIB_USEDEP}]
+	X? (
+		>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libxcb-1.9.1[${MULTILIB_USEDEP}]
+	)
+	gbm? ( >=virtual/libudev-208:=[${MULTILIB_USEDEP}] )
+	wayland? ( >=dev-libs/wayland-1.10[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}
+	X? ( >=x11-base/xcb-proto-1.8-r3 )
+"
+BDEPEND="
+	app-text/docbook-xml-dtd:4.2
+	dev-libs/libxslt
+	dev-util/wayland-scanner
+"
+
+MULTILIB_CHOST_TOOLS=(
+	/usr/bin/wflinfo$(get_exeext)
+)
+
+multilib_src_configure() {
+	local emesonargs=(
+		$(meson_feature X glx)
+		$(meson_feature wayland)
+		$(meson_feature X x11_egl)
+		$(meson_feature gbm)
+		$(meson_feature egl surfaceless_egl)
+		$(meson_native_true build-manpages)
+		-Dbuild-tests=false
+	)
+	meson_src_configure
+}
+
+multilib_src_install() {
+	meson_src_install
+
+	! use doc && rm -rf \
+		"${D}"/usr/share/doc/waffle1 \
+		"${D}"/usr/share/man/man{3,7}
+}
diff --git a/media-libs/waffle/waffle-9999.ebuild b/media-libs/waffle/waffle-9999.ebuild
index a4611e934598..968c882955b5 100644
--- a/media-libs/waffle/waffle-9999.ebuild
+++ b/media-libs/waffle/waffle-9999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2022 Gentoo Authors
+# Copyright 1999-2023 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -34,8 +34,9 @@ DEPEND="${RDEPEND}
 	X? ( >=x11-base/xcb-proto-1.8-r3 )
 "
 BDEPEND="
-	dev-libs/libxslt
 	app-text/docbook-xml-dtd:4.2
+	dev-libs/libxslt
+	dev-util/wayland-scanner
 "
 
 MULTILIB_CHOST_TOOLS=(