media-plugins/gst-plugins-libav: bump to 1.12.3

Updates bundled ffmpeg to v3.3.4 (used only with USE=libav) and a memory leak fix

Package-Manager: Portage-2.3.6, Repoman-2.3.2

1 files changed, 74 insertions, 0 deletions

diff --git a/media-plugins/gst-plugins-libav/gst-plugins-libav-1.12.3.ebuild b/media-plugins/gst-plugins-libav/gst-plugins-libav-1.12.3.ebuild
new file mode 100644
index 000000000000..bbc3a1fc3e21
--- /dev/null
+++ b/media-plugins/gst-plugins-libav/gst-plugins-libav-1.12.3.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eutils multilib-minimal
+
+MY_PN="gst-libav"
+DESCRIPTION="FFmpeg based gstreamer plugin"
+HOMEPAGE="https://gstreamer.freedesktop.org/modules/gst-libav.html"
+SRC_URI="https://gstreamer.freedesktop.org/src/${MY_PN}/${MY_PN}-${PV}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="1.0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~x86 ~amd64-fbsd ~x86-fbsd"
+IUSE="libav +orc"
+
+# XXX: bzip2/lzma are automagic
+# Move back to ${PV} deps of gstreamer/gst-plugins-base later; 1.10.4 had it reduced for lone security stabilization
+RDEPEND="
+	app-arch/bzip2
+	app-arch/xz-utils
+	>=dev-libs/glib-2.40.0:2[${MULTILIB_USEDEP}]
+	>=media-libs/gstreamer-1.12.0:1.0[${MULTILIB_USEDEP}]
+	>=media-libs/gst-plugins-base-1.12.0:1.0[${MULTILIB_USEDEP}]
+	!libav? ( >=media-video/ffmpeg-3.2.4:0=[${MULTILIB_USEDEP}] )
+	orc? ( >=dev-lang/orc-0.4.17[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.12
+	>=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]
+"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+RESTRICT="test" # FIXME: tests seem to get stuck at one point; investigate properly
+
+multilib_src_configure() {
+	GST_PLUGINS_BUILD=""
+	# Upstream dropped support for system libav and won't work
+	# for preserving its compat anymore, forcing us to rely on internal
+	# ffmpeg copy if we don't want to cause unresolvable blockers for
+	# libav setups.
+	# https://bugzilla.gnome.org/show_bug.cgi?id=758183
+	# Prefer system ffmpeg for -libav
+	local myconf
+
+	if use libav; then
+		ewarn "Using internal ffmpeg copy as upstream dropped"
+		ewarn "the support for compiling against system libav"
+		ewarn "http://bugzilla.gnome.org/show_bug.cgi?id=758183"
+	else
+		myconf="--with-system-libav"
+	fi
+
+	ECONF_SOURCE=${S} \
+	econf \
+		--disable-maintainer-mode \
+		--with-package-name="Gentoo GStreamer ebuild" \
+		--with-package-origin="https://www.gentoo.org" \
+		--disable-fatal-warnings \
+		$(use_enable orc) \
+		${myconf}
+}
+
+multilib_src_compile() {
+	# Don't build with -Werror
+	emake ERROR_CFLAGS=
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	prune_libtool_files --modules
+}