media-plugins/gst-plugins-libav: version bump to 1.6.1

Use ${PV} for gstreamer and gst-plugins-base dependency as all releases are coordinated for a while now, see also bug #565044.

Package-Manager: portage-2.2.23

1 files changed, 57 insertions, 0 deletions

diff --git a/media-plugins/gst-plugins-libav/gst-plugins-libav-1.6.1.ebuild b/media-plugins/gst-plugins-libav/gst-plugins-libav-1.6.1.ebuild
new file mode 100644
index 000000000000..38cd14cd0291
--- /dev/null
+++ b/media-plugins/gst-plugins-libav/gst-plugins-libav-1.6.1.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+
+inherit eutils flag-o-matic multilib-minimal
+
+MY_PN="gst-libav"
+DESCRIPTION="FFmpeg based gstreamer plugin"
+HOMEPAGE="http://gstreamer.freedesktop.org/modules/gst-libav.html"
+SRC_URI="http://gstreamer.freedesktop.org/src/${MY_PN}/${MY_PN}-${PV}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="1.0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
+IUSE="libav +orc"
+
+# XXX: bzip2/lzma are automagic
+RDEPEND="
+	app-arch/bzip2
+	app-arch/xz-utils
+	>=media-libs/gstreamer-${PV}:1.0[${MULTILIB_USEDEP}]
+	>=media-libs/gst-plugins-base-${PV}:1.0[${MULTILIB_USEDEP}]
+	!libav? ( >=media-video/ffmpeg-2.2:0=[${MULTILIB_USEDEP}] )
+	libav? ( >=media-video/libav-10:0=[${MULTILIB_USEDEP}] )
+	orc? ( >=dev-lang/orc-0.4.17[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.12
+	>=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]
+"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+multilib_src_configure() {
+	GST_PLUGINS_BUILD=""
+	# always use system ffmpeg/libav if possible
+	ECONF_SOURCE=${S} \
+	econf \
+		--disable-maintainer-mode \
+		--with-package-name="Gentoo GStreamer ebuild" \
+		--with-package-origin="https://www.gentoo.org" \
+		--disable-fatal-warnings \
+		--with-system-libav \
+		$(use_enable orc)
+}
+
+multilib_src_compile() {
+	# Don't build with -Werror
+	emake ERROR_CFLAGS=
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	prune_libtool_files --modules
+}