media-plugins/gst-plugins-vaapi: bump to 1.10.5 for upstream bug fixes

Package-Manager: Portage-2.3.5, Repoman-2.3.2

2 files changed, 62 insertions, 0 deletions

diff --git a/media-plugins/gst-plugins-vaapi/Manifest b/media-plugins/gst-plugins-vaapi/Manifest
index 10d3f773a9f2..40d603fd8356 100644
--- a/media-plugins/gst-plugins-vaapi/Manifest
+++ b/media-plugins/gst-plugins-vaapi/Manifest
@@ -1,2 +1,3 @@
 DIST gstreamer-vaapi-1.10.3.tar.xz 976704 SHA256 cea827066a152a6afa1d0c43544dfbda285238156d4c3b77f9d4037bbe79361e SHA512 6c3c9b35a8f2b6d58185a0447f1f458ad0d0432986496ac157cc349b169022788a3d3fbb0c529b740f972386ead79e1a8dddf49ef3218a783893f3f83abc1ddb WHIRLPOOL 1229bc6be5e0e97e61ce4cd5fc61e90337de4dcefbf932a2265611d67a79a85b87d3d6be1df5172be4a3faa431337f97609097eb9256cfdbe0b624587d32af45
 DIST gstreamer-vaapi-1.10.4.tar.xz 979112 SHA256 03e690621594d9f9495d86c7dac8b8590b3a150462770ed070dc76f66a70de75 SHA512 b78470367e9ab4c762a8948bc9412147d209a94def07334d6c5790b3bcb9607a80c8cf3fc3f0636e975d4ebf4aca0adbcff10a1bc1499c78b993ff21ee496c2b WHIRLPOOL 90cff1061ad3b73705446a43adb2aa7d29f064f60989a963a30c6018fd13636e66fddcfa994c906dc8fae5af47d673794cbf475622c1158f22ed5ec68c7c5668
+DIST gstreamer-vaapi-1.10.5.tar.xz 978260 SHA256 b61e5b0a3f2c4b93974749dcd8e1e7bddfd7cc740573edb557bcae84cf911691 SHA512 8e8801c8a6d089ccb3e456171fb8030e9a34f517bb1fef411dd1b8bfbc09230511c112f1fea4d3610acc705674a645c6730e5022406d2de5b73ec1c093a69df9 WHIRLPOOL 8a20cafa061735ca24953c893420de95a3fbbbb765aff196ba23ef726b72ec67ff14f1074245ebb35dae5381c023cfe0428b53614fe749c8ab22f9537a37f02f
diff --git a/media-plugins/gst-plugins-vaapi/gst-plugins-vaapi-1.10.5.ebuild b/media-plugins/gst-plugins-vaapi/gst-plugins-vaapi-1.10.5.ebuild
new file mode 100644
index 000000000000..13ade4bbf85a
--- /dev/null
+++ b/media-plugins/gst-plugins-vaapi/gst-plugins-vaapi-1.10.5.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eutils multilib-minimal
+
+MY_PN="gstreamer-vaapi"
+DESCRIPTION="Hardware accelerated video decoding through VA-API plugin for GStreamer"
+HOMEPAGE="https://cgit.freedesktop.org/gstreamer/gstreamer-vaapi"
+SRC_URI="https://gstreamer.freedesktop.org/src/${MY_PN}/${MY_PN}-${PV}.tar.xz"
+
+LICENSE="LGPL-2.1"
+SLOT="1.0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="+drm egl opengl wayland +X"
+REQUIRED_USE="|| ( drm opengl wayland X )"
+
+RDEPEND="
+	>=dev-libs/glib-2.40:2[${MULTILIB_USEDEP}]
+	>=media-libs/gstreamer-${PV}:${SLOT}[${MULTILIB_USEDEP}]
+	>=media-libs/gst-plugins-base-${PV}:${SLOT}[${MULTILIB_USEDEP}]
+	>=media-libs/gst-plugins-bad-${PV}:${SLOT}[opengl?,${MULTILIB_USEDEP}]
+	>=x11-libs/libva-1.4.0[drm?,X?,opengl?,wayland?,${MULTILIB_USEDEP}]
+	drm? (
+		>=virtual/libudev-208:=[${MULTILIB_USEDEP}]
+		>=x11-libs/libdrm-2.4.46[${MULTILIB_USEDEP}] )
+	egl? (
+		>=media-libs/gst-plugins-bad-${PV}:${SLOT}[opengl,${MULTILIB_USEDEP}] )
+	opengl? (
+		>=virtual/opengl-7.0-r1[${MULTILIB_USEDEP}]
+		>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libXrandr-1.4.2[${MULTILIB_USEDEP}] )
+	wayland? ( >=dev-libs/wayland-1.0.6[${MULTILIB_USEDEP}] )
+	X? (
+		>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libXrandr-1.4.2[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.12
+	>=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]
+"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+multilib_src_configure() {
+	ECONF_SOURCE=${S} \
+	econf \
+		--disable-static \
+		$(use_enable drm) \
+		$(use_enable egl) \
+		$(use_enable opengl glx) \
+		$(use_enable wayland) \
+		$(use_enable X x11)
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	prune_libtool_files --modules
+}