proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 56 insertions, 0 deletions

diff --git a/media-sound/audacious/audacious-3.4.1.ebuild b/media-sound/audacious/audacious-3.4.1.ebuild
new file mode 100644
index 000000000000..bcff67cda5b1
--- /dev/null
+++ b/media-sound/audacious/audacious-3.4.1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit eutils
+
+MY_P="${P/_/-}"
+S="${WORKDIR}/${MY_P}"
+DESCRIPTION="Audacious Player - Your music, your way, no exceptions"
+HOMEPAGE="http://audacious-media-player.org/"
+SRC_URI="http://distfiles.audacious-media-player.org/${MY_P}.tar.bz2
+	 mirror://gentoo/gentoo_ice-xmms-0.2.tar.bz2"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="alpha amd64 ~arm hppa ppc ppc64 sparc x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux"
+
+IUSE="chardet nls"
+
+RDEPEND=">=dev-libs/dbus-glib-0.60
+	>=dev-libs/glib-2.28
+	dev-libs/libxml2
+	>=x11-libs/cairo-1.2.6
+	>=x11-libs/pango-1.8.0
+	x11-libs/gtk+:3"
+
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	chardet? ( >=app-i18n/libguess-1.1 )
+	nls? ( dev-util/intltool )"
+
+PDEPEND="~media-plugins/audacious-plugins-3.4.1"
+
+src_configure() {
+	# D-Bus is a mandatory dependency, remote control,
+	# session management and some plugins depend on this.
+	# Building without D-Bus is *unsupported* and a USE-flag
+	# will not be added due to the bug reports that will result.
+	# Bugs #197894, #199069, #207330, #208606
+	econf \
+		--enable-dbus \
+		$(use_enable chardet) \
+		$(use_enable nls)
+}
+
+src_install() {
+	default
+	dodoc AUTHORS
+
+	# Gentoo_ice skin installation; bug #109772
+	insinto /usr/share/audacious/Skins/gentoo_ice
+	doins "${WORKDIR}"/gentoo_ice/*
+	docinto gentoo_ice
+	dodoc "${WORKDIR}"/README
+}