proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 60 insertions, 0 deletions

diff --git a/media-sound/gmpc/gmpc-11.8.16-r1.ebuild b/media-sound/gmpc/gmpc-11.8.16-r1.ebuild
new file mode 100644
index 000000000000..50a7b101c362
--- /dev/null
+++ b/media-sound/gmpc/gmpc-11.8.16-r1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=4
+VALA_MIN_API_VERSION=0.12
+
+inherit autotools eutils gnome2-utils vala
+
+DESCRIPTION="A GTK+2 client for the Music Player Daemon"
+HOMEPAGE="http://gmpc.wikia.com/wiki/Gnome_Music_Player_Client"
+SRC_URI="http://download.sarine.nl/Programs/gmpc/11.8/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 ppc x86"
+IUSE="nls xspf +unique"
+
+RDEPEND="dev-db/sqlite:3
+	>=dev-libs/glib-2.16:2
+	dev-libs/libxml2:2
+	>=media-libs/libmpd-11.8
+	net-libs/libsoup:2.4
+	>=x11-libs/gtk+-2.18:2
+	x11-libs/libX11
+	x11-themes/hicolor-icon-theme
+	unique? ( dev-libs/libunique:1 )
+	xspf? ( >=media-libs/libxspf-1.2 )"
+DEPEND="${RDEPEND}
+	$(vala_depend)
+	app-text/gnome-doc-utils
+	>=dev-util/gob-2.0.17
+	virtual/pkgconfig
+	nls? ( dev-util/intltool
+		sys-devel/gettext )"
+
+DOCS=( AUTHORS README )
+
+src_prepare() {
+	epatch "${FILESDIR}"/${P}-underlinking.patch \
+		"${FILESDIR}"/${P}-icons.patch
+	sed -i -e "s:AM_CONFIG_HEADER:AC_CONFIG_HEADERS:" configure.ac || die
+	eautoreconf
+	vala_src_prepare
+}
+
+src_configure() {
+	econf \
+		--disable-static \
+		--disable-libspiff \
+		--disable-appindicator \
+		--enable-mmkeys \
+		$(use_enable nls) \
+		$(use_enable unique) \
+		$(use_enable xspf libxspf)
+}
+
+pkg_preinst() { gnome2_icon_savelist; }
+pkg_postinst() { gnome2_icon_cache_update; }
+pkg_postrm() { gnome2_icon_cache_update; }