media-sound/musescore: 3.4.1 bump + 9999 sync

1) updated use flags (added osc, omr, sfz, vorbis changed to +sf3)
2) sorted and added config args

Package-Manager: Portage-2.3.86, Repoman-2.3.20
Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>

4 files changed, 126 insertions, 9 deletions

diff --git a/media-sound/musescore/Manifest b/media-sound/musescore/Manifest
index 609f0dccd452..eeefb7ac66bc 100644
--- a/media-sound/musescore/Manifest
+++ b/media-sound/musescore/Manifest
@@ -2,3 +2,4 @@ DIST MuseScore_General-0.1.6.tar.bz2 35109226 BLAKE2B 62a22e50d4c10ab08f0affd728
 DIST MuseScore_General-0.1.8.tar.bz2 35107290 BLAKE2B 65a0f78077a89fbf590fc47e83009f1029492ddb5a6bc411798c141903dbeffc5aa8b32fcead672e886878d2c9134c33c3c38e438e293a8135eca8394f880b32 SHA512 bdc706139309524841fdfe738e156f95d2d4c1716c09ce2984f9de5f205f39d3adffd7327a3957727015b7a612bab99c228ca26d9b0dcaf077991794585169c9
 DIST musescore-3.3.4.tar.gz 62827836 BLAKE2B 55e4c14539ac6227f0cc2dfb50adae920e63f9cf054a90a4c39f92c608a3ccb17c395070f77380997b367b48db72d96104117e02f486dcad26c0ea08aedce329 SHA512 c224e391daadf8d33cbf9d42e6a055290d7821abe7141e4927a77f1c7df6a57cbcbe5277248deb39d368547f17423ee9a4b5bc6cde8f27bc5646e83c6c4ff082
 DIST musescore-3.3.tar.gz 64453809 BLAKE2B 278ca68e3a2432750356902360ac6882abaf763d3e512aa588e2b0eb7c58f8ffdab111ec3edaa9bf058a41ab5bce26f05a9a618def0c094376a6a4dbea7340ef SHA512 b7d228d957d674868474ae6a94afbeaa530d2d2e7688b9be91b77237066071920034a3b5e2241399543b4fe8d73d97ba605584cb0c0f67d2026ca212a13dbaea
+DIST musescore-3.4.1.tar.gz 62951880 BLAKE2B fd15545a6bd5632650654a86063a8152b3ade7148ec4c4986ed501397f74e4a9f7db6574f1cd0ee1d512b0cb4e5b90e890ef028f3acf7a9a55989bda05bfe178 SHA512 4d76d6990595a77db55801d7ec3c4790718e8633e173daa34a2b2e8477384cbbce84257a797b2e9652ba8d8a8705a41d9e33a2882225415964061e57a1a82861
diff --git a/media-sound/musescore/metadata.xml b/media-sound/musescore/metadata.xml
index f0d90452cf33..0a5292967923 100644
--- a/media-sound/musescore/metadata.xml
+++ b/media-sound/musescore/metadata.xml
@@ -10,8 +10,11 @@
 		<remote-id type="github">musescore/MuseScore</remote-id>
 	</upstream>
 	<use>
+		<flag name="osc">Enable OSC remote control protocol</flag>
+		<flag name="omr">Enable PDF import (OMR - optical music recognition)</flag>
 		<flag name="portmidi">Enable support for building against <pkg>media-libs/portmidi</pkg></flag>
-		<flag name="vorbis">Enable SoundFont support using  <pkg>media-libs/libvorbis</pkg></flag>
+		<flag name="sf3">Enable SoundFont 3 support using  <pkg>media-libs/libvorbis</pkg></flag>
+		<flag name="sfz">Enable experimental SFZ sampler</flag>
 		<flag name="webengine">Use <pkg>dev-qt/qtwebengine</pkg> for embedded web browser</flag>
 	</use>
 </pkgmetadata>
diff --git a/media-sound/musescore/musescore-3.4.1.ebuild b/media-sound/musescore/musescore-3.4.1.ebuild
new file mode 100644
index 000000000000..fb4ff90af180
--- /dev/null
+++ b/media-sound/musescore/musescore-3.4.1.ebuild
@@ -0,0 +1,102 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+CMAKE_MAKEFILE_GENERATOR="emake"
+CHECKREQS_DISK_BUILD=3500M
+inherit cmake xdg check-reqs
+
+DESCRIPTION="WYSIWYG Music Score Typesetter"
+HOMEPAGE="https://musescore.org/"
+# MuseScore_General-0.1.3.tar.bz2 packaged from https://ftp.osuosl.org/pub/musescore/soundfont/MuseScore_General/
+# It has to be repackaged because the files are not versioned, current version can be found in VERSION file there.
+SRC_URI="https://github.com/musescore/MuseScore/archive/v${PV}.tar.gz -> ${P}.tar.gz
+	https://dev.gentoo.org/~fordfrog/distfiles/MuseScore_General-0.1.8.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="alsa debug jack mp3 osc omr portaudio portmidi pulseaudio +sf3 sfz webengine"
+REQUIRED_USE="portmidi? ( portaudio )"
+
+BDEPEND="
+	dev-qt/linguist-tools:5
+	virtual/pkgconfig
+"
+DEPEND="
+	dev-qt/designer:5
+	dev-qt/qtconcurrent:5
+	dev-qt/qtcore:5
+	dev-qt/qtdeclarative:5
+	dev-qt/qtgui:5
+	dev-qt/qthelp:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtprintsupport:5
+	dev-qt/qtquickcontrols2:5
+	>=dev-qt/qtsingleapplication-2.6.1_p20171024
+	dev-qt/qtsvg:5
+	dev-qt/qtxml:5
+	dev-qt/qtxmlpatterns:5
+	>=media-libs/freetype-2.5.2
+	media-libs/libsndfile
+	sys-libs/zlib:=
+	alsa? ( >=media-libs/alsa-lib-1.0.0 )
+	jack? ( virtual/jack )
+	mp3? ( media-sound/lame )
+	omr? ( app-text/poppler )
+	portaudio? ( media-libs/portaudio )
+	portmidi? ( media-libs/portmidi )
+	pulseaudio? ( media-sound/pulseaudio )
+	sf3? ( media-libs/libvorbis )
+	webengine? ( dev-qt/qtwebengine:5[widgets] )
+"
+RDEPEND="${DEPEND}"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-3.0.1-man-pages.patch"
+)
+
+S="${WORKDIR}/MuseScore-${PV}"
+
+src_prepare() {
+	cmake_src_prepare
+
+	# Move soundfonts to the correct directory
+	mv "${WORKDIR}"/sound/* "${S}"/share/sound/ || die "Failed to move soundfont files"
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DAEOLUS=OFF # does not compile
+		-DBUILD_ALSA="$(usex alsa)"
+		-DBUILD_CRASH_REPORTER=OFF
+		-DBUILD_JACK="$(usex jack)"
+		-DBUILD_LAME="$(usex mp3)"
+		-DBUILD_PCH=ON
+		-DBUILD_PORTAUDIO="$(usex portaudio)"
+		-DBUILD_PORTMIDI="$(usex portmidi)"
+		-DBUILD_PULSEAUDIO="$(usex pulseaudio)"
+		-DBUILD_SHARED_LIBS=ON
+		-DBUILD_TELEMETRY_MODULE=ON
+		-DBUILD_WEBENGINE="$(usex webengine)"
+		-DCMAKE_SKIP_RPATH=ON
+		-DDOWNLOAD_SOUNDFONT=OFF
+		-DHAS_AUDIOFILE=ON
+		-DOCR=OFF
+		-DOMR="$(usex omr)"
+		-DSOUNDFONT3=ON
+		-DZERBERUS="$(usex sfz)"
+		-DUSE_PATH_WITH_EXPLICIT_QT_VERSION=ON
+		-DUSE_SYSTEM_FREETYPE=ON
+		-DUSE_SYSTEM_POPPLER=ON
+		-DUSE_SYSTEM_QTSINGLEAPPLICATION=ON
+	)
+	cmake_src_configure
+}
+
+src_compile() {
+	cd "${BUILD_DIR}" || die
+	cmake_build -j1 lrelease manpages
+	cmake_src_compile
+}
diff --git a/media-sound/musescore/musescore-9999.ebuild b/media-sound/musescore/musescore-9999.ebuild
index 5d3ba673cd37..6157b14ce4af 100644
--- a/media-sound/musescore/musescore-9999.ebuild
+++ b/media-sound/musescore/musescore-9999.ebuild
@@ -17,7 +17,7 @@ EGIT_REPO_URI="https://github.com/${PN}/MuseScore.git"
 LICENSE="GPL-2"
 SLOT="0"
 KEYWORDS=""
-IUSE="alsa debug jack mp3 portaudio portmidi pulseaudio vorbis webengine"
+IUSE="alsa debug jack mp3 osc omr portaudio portmidi pulseaudio +sf3 sfz webengine"
 REQUIRED_USE="portmidi? ( portaudio )"
 
 BDEPEND="
@@ -44,10 +44,11 @@ DEPEND="
 	alsa? ( >=media-libs/alsa-lib-1.0.0 )
 	jack? ( virtual/jack )
 	mp3? ( media-sound/lame )
+	omr? ( app-text/poppler )
 	portaudio? ( media-libs/portaudio )
 	portmidi? ( media-libs/portmidi )
 	pulseaudio? ( media-sound/pulseaudio )
-	vorbis? ( media-libs/libvorbis )
+	sf3? ( media-libs/libvorbis )
 	webengine? ( dev-qt/qtwebengine:5[widgets] )
 "
 RDEPEND="${DEPEND}"
@@ -70,19 +71,29 @@ src_prepare() {
 
 src_configure() {
 	local mycmakeargs=(
-		-DCMAKE_SKIP_RPATH=ON
-		-DDOWNLOAD_SOUNDFONT=OFF
-		-DUSE_SYSTEM_QTSINGLEAPPLICATION=ON
-		-DUSE_PATH_WITH_EXPLICIT_QT_VERSION=ON
-		-DUSE_SYSTEM_FREETYPE=ON
+		-DAEOLUS=OFF # does not compile
 		-DBUILD_ALSA="$(usex alsa)"
+		-DBUILD_CRASH_REPORTER=OFF
 		-DBUILD_JACK="$(usex jack)"
 		-DBUILD_LAME="$(usex mp3)"
+		-DBUILD_PCH=ON
 		-DBUILD_PORTAUDIO="$(usex portaudio)"
 		-DBUILD_PORTMIDI="$(usex portmidi)"
 		-DBUILD_PULSEAUDIO="$(usex pulseaudio)"
-		-DSOUNDFONT3="$(usex vorbis)"
+		-DBUILD_SHARED_LIBS=ON
+		-DBUILD_TELEMETRY_MODULE=ON
 		-DBUILD_WEBENGINE="$(usex webengine)"
+		-DCMAKE_SKIP_RPATH=ON
+		-DDOWNLOAD_SOUNDFONT=OFF
+		-DHAS_AUDIOFILE=ON
+		-DOCR=OFF
+		-DOMR="$(usex omr)"
+		-DSOUNDFONT3=ON
+		-DZERBERUS="$(usex sfz)"
+		-DUSE_PATH_WITH_EXPLICIT_QT_VERSION=ON
+		-DUSE_SYSTEM_FREETYPE=ON
+		-DUSE_SYSTEM_POPPLER=ON
+		-DUSE_SYSTEM_QTSINGLEAPPLICATION=ON
 	)
 	cmake_src_configure
 }