proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 53 insertions, 0 deletions

diff --git a/media-sound/ncmpc/ncmpc-0.24.ebuild b/media-sound/ncmpc/ncmpc-0.24.ebuild
new file mode 100644
index 000000000000..ca8605f51b64
--- /dev/null
+++ b/media-sound/ncmpc/ncmpc-0.24.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit multilib
+
+DESCRIPTION="A ncurses client for the Music Player Daemon (MPD)"
+HOMEPAGE="http://www.musicpd.org/clients/ncmpc/"
+SRC_URI="http://www.musicpd.org/download/${PN}/${PV%.*}/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 hppa ppc ppc64 sparc x86"
+IUSE="artist-screen chat-screen colors debug +help-screen key-screen lirc lyrics-screen mouse nls search-screen song-screen"
+
+RDEPEND=">=dev-libs/glib-2.12:2
+	>=media-libs/libmpdclient-2.3
+	sys-libs/ncurses
+	lirc? ( app-misc/lirc )
+	nls? ( sys-libs/ncurses[unicode] )"
+DEPEND="${RDEPEND}
+	app-arch/xz-utils
+	virtual/pkgconfig"
+
+DOCS=( AUTHORS NEWS README doc/config.sample doc/keys.sample )
+
+src_configure() {
+	# upstream lirc doesn't have pkg-config file wrt #250015
+	if use lirc; then
+		export LIBLIRCCLIENT_CFLAGS="-I/usr/include/lirc"
+		export LIBLIRCCLIENT_LIBS="-llirc_client"
+	fi
+
+	# use_with lyrics-screen is for multilib
+	econf \
+		--docdir=/usr/share/doc/${PF} \
+		$(use_enable artist-screen) \
+		$(use_enable chat-screen) \
+		$(use_enable colors) \
+		$(use_enable debug) \
+		$(use_enable help-screen) \
+		$(use_enable key-screen) \
+		$(use_enable lirc) \
+		$(use_enable lyrics-screen) \
+		$(use_enable mouse) \
+		$(use_enable nls locale) \
+		$(use_enable nls multibyte) \
+		$(use_enable nls) \
+		$(use_enable search-screen) \
+		$(use_enable song-screen) \
+		$(use_with lyrics-screen lyrics-plugin-dir /usr/$(get_libdir)/ncmpc/lyrics)
+}