media-sound/ripperx: Port to EAPI 7

Package-Manager: Portage-3.0.9, Repoman-3.0.2
Signed-off-by: David Seifert <soap@gentoo.org>

1 files changed, 19 insertions, 22 deletions

diff --git a/media-sound/ripperx/ripperx-2.7.3.ebuild b/media-sound/ripperx/ripperx-2.7.3.ebuild
index 96bb4e62f35e..2656cb3b070a 100644
--- a/media-sound/ripperx/ripperx-2.7.3.ebuild
+++ b/media-sound/ripperx/ripperx-2.7.3.ebuild
@@ -1,47 +1,44 @@
-# Copyright 1999-2014 Gentoo Foundation
+# Copyright 1999-2020 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=5
-inherit eutils
+EAPI=7
 
-MY_P=${P/x/X}
-MY_PN=${PN/x/X}
+inherit desktop
 
-DESCRIPTION="a GTK program to rip CD audio tracks and encode them to the Ogg, MP3, or FLAC formats"
+DESCRIPTION="GTK program to rip CD audio tracks to Ogg, MP3 or FLAC"
 HOMEPAGE="https://sourceforge.net/projects/ripperx"
-SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"
+SRC_URI="mirror://sourceforge/${PN}/${P/x/X}.tar.gz"
 
 LICENSE="GPL-2"
 SLOT="0"
 KEYWORDS="amd64 ppc x86"
 IUSE="nls"
 
-RDEPEND="media-libs/id3lib
+RDEPEND="
+	media-libs/id3lib
 	media-sound/cdparanoia
 	media-sound/lame
 	x11-libs/gtk+:2"
-DEPEND="${RDEPEND}
+DEPEND="${RDEPEND}"
+BDEPEND="
 	virtual/pkgconfig
 	nls? ( sys-devel/gettext )"
 
-S=${WORKDIR}/${MY_P}
+S="${WORKDIR}/${P/x/X}"
 
-src_prepare() {
-	# AC_CHECK_LIB(m, ceilf, [], [MATH_LIB="-lm" MATH_LIB=""]) #401867
-	sed -i -e '/ripperX_LDADD/s:=:= -lm:' src/Makefile.in || die
-
-	epatch \
-		"${FILESDIR}"/${P}-ldflags.patch \
-		"${FILESDIR}"/${P}-pkgconfig.patch
-}
+PATCHES=(
+	"${FILESDIR}"/${P}-ceilf-underlink.patch
+	"${FILESDIR}"/${P}-ldflags.patch
+	"${FILESDIR}"/${P}-pkgconfig.patch
+)
 
 src_configure() {
 	econf $(use_enable nls)
 }
 
 src_install() {
-	emake DESTDIR="${D}" install
-	dodoc BUGS CHANGES FAQ README* TODO
-	doicon src/xpms/${MY_PN}-icon.xpm
-	make_desktop_entry ${MY_PN} ${MY_PN} ${MY_PN}-icon
+	default
+
+	doicon src/xpms/ripperX-icon.xpm
+	make_desktop_entry ripperX ripperX ripperX-icon
 }