media-sound/sonic-visualiser: bump to 4.1

Package-Manager: Portage-2.3.103, Repoman-2.3.23
Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>

2 files changed, 125 insertions, 0 deletions

diff --git a/media-sound/sonic-visualiser/Manifest b/media-sound/sonic-visualiser/Manifest
index bbe58788fa48..071af760de9b 100644
--- a/media-sound/sonic-visualiser/Manifest
+++ b/media-sound/sonic-visualiser/Manifest
@@ -1 +1,2 @@
 DIST sonic-visualiser-4.0.1.tar.gz 6649178 BLAKE2B c231833f7cc6228d450600e5cbc6a6db85d0aa784ce67a225bedb1393ca82a99bca492912bbaf8bf87f5fcce48e57facc3f216b057233b53f596ccd71835d174 SHA512 6557d7c90618f7f2c18f8bb0058b8cd74a084f26376999074b9d5f23f04e1548b7e82ccbb73a301fa68c1d2f047810d312e568a85c9c7f3f25da9ec9b00c4220
+DIST sonic-visualiser-4.1.tar.gz 6535840 BLAKE2B b3afdb2026405148e2efb217e960a4e70fd8efbe3779c6cc3671b17a808f12e288efb89bbd5200da9ccfc8bdbd0c684d555f7394aab8e67d2963fd84f967da0c SHA512 57edfc52ddbc9198a6608460a8f4e4fc2a382588f2881b7ea99cc738d7944d66c942f24218a303fb20eaa698ee365f29006c985f2385afd7f5c27fec5a241adb
diff --git a/media-sound/sonic-visualiser/sonic-visualiser-4.1.ebuild b/media-sound/sonic-visualiser/sonic-visualiser-4.1.ebuild
new file mode 100644
index 000000000000..e2042ae91787
--- /dev/null
+++ b/media-sound/sonic-visualiser/sonic-visualiser-4.1.ebuild
@@ -0,0 +1,124 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools desktop qmake-utils xdg
+
+DESCRIPTION="Music audio files viewer and analiser"
+HOMEPAGE="https://www.sonicvisualiser.org/"
+SRC_URI="https://code.soundsoftware.ac.uk/attachments/download/2717/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="id3tag jack mad ogg opus osc +portaudio pulseaudio"
+
+BDEPEND="
+	dev-qt/qttest:5
+	sys-devel/autoconf-archive
+	virtual/pkgconfig
+"
+RDEPEND="
+	app-arch/bzip2
+	>=dev-libs/capnproto-0.6:=
+	dev-libs/serd
+	dev-libs/sord
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	media-libs/alsa-lib
+	media-libs/dssi
+	media-libs/ladspa-sdk
+	media-libs/liblrdf
+	media-libs/libsamplerate
+	media-libs/libsndfile
+	media-libs/rubberband
+	media-libs/speex
+	media-libs/vamp-plugin-sdk
+	sci-libs/fftw:3.0=
+	id3tag? ( media-libs/libid3tag )
+	jack? ( virtual/jack )
+	mad? ( media-libs/libmad )
+	ogg? (
+		media-libs/libfishsound
+		media-libs/liboggz
+	)
+	opus? ( media-libs/opusfile )
+	osc? ( media-libs/liblo )
+	portaudio? ( >=media-libs/portaudio-19 )
+	pulseaudio? ( media-sound/pulseaudio )
+"
+DEPEND="${RDEPEND}"
+
+REQUIRED_USE="|| ( jack pulseaudio portaudio )"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-4.0.1-notest.patch"
+)
+
+sv_disable_opt() {
+	einfo "Disabling $1"
+	for i in . svapp svcore svgui ; do
+		sed -i -e "/$1/d" "${S}/$i/configure.ac" || die "failed to remove $1 support"
+	done
+}
+
+src_prepare() {
+	default
+
+	use id3tag || sv_disable_opt id3tag
+	use jack || sv_disable_opt jack
+	use mad || sv_disable_opt mad
+	use ogg || sv_disable_opt fishsound
+	use ogg || sv_disable_opt oggz
+	use opus || sv_disable_opt opus
+	use osc || sv_disable_opt liblo
+	use portaudio || sv_disable_opt portaudio
+	use pulseaudio || sv_disable_opt libpulse
+
+	# capnproto 0.7 requires c++14 now
+	sed -e 's/AX_CXX_COMPILE_STDCXX_11/AX_CXX_COMPILE_STDCXX_14/g' \
+		-i configure.ac \
+		-i */configure.ac \
+		|| die
+
+	eautoreconf
+}
+
+src_configure() {
+	export QMAKE="$(qt5_get_bindir)"/qmake
+	econf
+	eqmake5 -r sonic-visualiser.pro
+	sed -e 's/std=gnu++11/std=gnu++14/g' \
+		-i Makefile.* \
+		-i checker/Makefile.* \
+		|| die
+}
+
+src_test() {
+	for i in test-svcore-base test-svcore-data-fileio test-svcore-data-model test-svcore-system ; do
+		einfo "Running ${i}"
+		HOME="${T}" ./${i} || die
+	done
+}
+
+src_install() {
+	dobin ${PN} piper-vamp-simple-server piper-convert vamp-plugin-load-checker
+	dodoc README*
+
+	#install samples
+	insinto /usr/share/${PN}/samples
+	doins samples/*
+
+	# desktop entry
+	doicon icons/sv-icon.svg
+	domenu sonic-visualiser.desktop
+
+	# mime types
+	insinto /usr/share/mime/packages
+	doins "${FILESDIR}/${PN}.xml"
+}