media-sound/soundkonverter: Prepare for media-libs/phonon losing qt5

Package-Manager: Portage-2.3.24, Repoman-2.3.6

1 files changed, 57 insertions, 0 deletions

diff --git a/media-sound/soundkonverter/soundkonverter-3.0.1-r1.ebuild b/media-sound/soundkonverter/soundkonverter-3.0.1-r1.ebuild
new file mode 100644
index 000000000000..3dea21807b66
--- /dev/null
+++ b/media-sound/soundkonverter/soundkonverter-3.0.1-r1.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit kde5
+
+DESCRIPTION="Frontend to various audio converters"
+HOMEPAGE="https://www.linux-apps.com/search?projectSearchText=soundKonverter
+	https://github.com/dfaust/soundkonverter"
+SRC_URI="https://github.com/dfaust/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+COMMON_DEPEND="
+	$(add_frameworks_dep kcompletion)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kdelibs4support)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep knotifications)
+	$(add_frameworks_dep kservice)
+	$(add_frameworks_dep ktextwidgets)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_frameworks_dep kxmlgui)
+	$(add_frameworks_dep solid)
+	$(add_kdeapps_dep libkcddb)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtwidgets)
+	$(add_qt_dep qtxml)
+	media-libs/phonon[qt5(+)]
+	>=media-libs/taglib-1.10
+	media-sound/cdparanoia
+"
+DEPEND="${COMMON_DEPEND}
+	sys-devel/gettext
+"
+RDEPEND="${COMMON_DEPEND}
+	!media-sound/soundkonverter:4
+"
+
+PATCHES=( "${FILESDIR}/${PN}-3.0.0-deps.patch" )
+
+S="${WORKDIR}"/${P}/src
+
+pkg_postinst() {
+	kde5_pkg_postinst
+
+	elog "soundKonverter optionally supports many different audio formats."
+	elog "You will need to install the appropriate encoding packages for the"
+	elog "formats you require. For a full listing, consult the README file"
+	elog "in /usr/share/doc/${PF}"
+}