proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 55 insertions, 0 deletions

diff --git a/media-video/qx11grab/qx11grab-0.4.12.ebuild b/media-video/qx11grab/qx11grab-0.4.12.ebuild
new file mode 100644
index 000000000000..a553c043b2f0
--- /dev/null
+++ b/media-video/qx11grab/qx11grab-0.4.12.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit cmake-utils
+
+DESCRIPTION="X11 desktop video grabber tray"
+HOMEPAGE="http://qx11grab.hjcms.de/"
+SRC_URI="http://qx11grab.hjcms.de/downloads/${PV}/${P}.tar.xz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="libav kde opengl pulseaudio"
+
+RDEPEND="
+	>=dev-qt/qtcore-4.7.4:4
+	>=dev-qt/qtdbus-4.7.4:4
+	>=dev-qt/qtgui-4.7.4:4[accessibility]
+	>=media-libs/alsa-lib-1.0.26
+	>=media-libs/fontconfig-2.4
+	>=media-libs/freetype-2.4:2
+	>=sys-apps/dbus-1.6.4
+	>=x11-libs/libX11-1.3.4
+	>=x11-libs/libXrandr-1.3
+	libav? ( >=media-video/libav-9:0=[X,encode,truetype] )
+	!libav? ( >=media-video/ffmpeg-1.1:0=[X,encode,truetype] )
+	kde? ( kde-base/kdelibs:4 )
+	opengl? ( >=dev-qt/qtopengl-4.7.4:4 )
+	pulseaudio? ( media-sound/pulseaudio )
+"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	kde? ( dev-util/automoc )
+"
+PDEPEND="virtual/freedesktop-icon-theme"
+
+src_prepare() {
+	cmake-utils_src_prepare
+
+	# install docs into standard Gentoo location
+	sed -i -e "/DESTINATION share/ s:\${CMAKE_PROJECT_NAME}:doc/${PF}:" \
+		CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_enable kde KDE_SUPPORT)
+		$(cmake-utils_use_enable opengl)
+		$(cmake-utils_use_enable pulseaudio PULSE)
+	)
+	cmake-utils_src_configure
+}