net-analyzer/angst: CFLAGS=-fcommon EAPI=7 IUSE=debug

Package-Manager: Portage-2.3.86, Repoman-2.3.20
Closes: https://bugs.gentoo.org/show_bug.cgi?id=707030
Signed-off-by: Jeroen Roovers <jer@gentoo.org>

1 files changed, 45 insertions, 0 deletions

diff --git a/net-analyzer/angst/angst-0.4b-r3.ebuild b/net-analyzer/angst/angst-0.4b-r3.ebuild
new file mode 100644
index 000000000000..8054d460f586
--- /dev/null
+++ b/net-analyzer/angst/angst-0.4b-r3.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit flag-o-matic toolchain-funcs
+
+DESCRIPTION="an active sniffer that provides methods for aggressive sniffing on switched LANs"
+HOMEPAGE="http://angst.sourceforge.net/"
+SRC_URI="http://angst.sourceforge.net/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="debug"
+
+DEPEND="
+	net-libs/libpcap
+	net-libs/libnet:1.0
+"
+RDEPEND="
+	${DEPEND}
+"
+PATCHES=(
+	"${FILESDIR}"/${PV}-flags.patch
+	"${FILESDIR}"/${PV}-libnet-1.0.patch
+)
+
+src_configure() {
+	append-cflags -fcommon
+	use debug && append-cppflags -DDEBUG
+}
+
+src_compile() {
+	emake \
+		CFLAGS="${CFLAGS}" \
+		LDFLAGS="${LDFLAGS}" \
+		CC="$(tc-getCC)" \
+		-f Makefile.linux
+}
+
+src_install() {
+	dosbin angst
+	doman angst.8
+	dodoc README TODO ChangeLog
+}