net-analyzer/jffnms: Drop app-mobilephone/smsclient dependency.

Package-Manager: Portage-2.3.5, Repoman-2.3.2

1 files changed, 56 insertions, 0 deletions

diff --git a/net-analyzer/jffnms/jffnms-0.9.4-r1.ebuild b/net-analyzer/jffnms/jffnms-0.9.4-r1.ebuild
new file mode 100644
index 000000000000..ddbea9ec4ebb
--- /dev/null
+++ b/net-analyzer/jffnms/jffnms-0.9.4-r1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit user
+
+DESCRIPTION="Network Management and Monitoring System"
+HOMEPAGE="http://www.jffnms.org/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tgz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="mysql postgres snmp"
+
+RDEPEND="
+	dev-lang/php[apache2,cli,gd,mysql?,postgres?,session,snmp,sockets,wddx]
+	dev-php/PEAR-PEAR
+	media-gfx/graphviz
+	media-libs/gd
+	net-analyzer/fping
+	net-analyzer/net-snmp
+	net-analyzer/nmap
+	net-analyzer/rrdtool[graph]
+	sys-apps/diffutils
+"
+
+pkg_setup() {
+	enewgroup jffnms
+	enewuser jffnms -1 /bin/bash -1 jffnms,apache
+}
+
+src_install(){
+	local INSTALL_DIR="/opt/${PN}"
+	local IMAGE_DIR="${D}${INSTALL_DIR}"
+
+	insinto "${INSTALL_DIR}"
+	doins -r *
+
+	rm -f "${IMAGE_DIR}/LICENSE"
+
+	# Clean up Windows related stuff
+	rm -f "${IMAGE_DIR}"/*.win32.txt
+	rm -rf "${IMAGE_DIR}"/docs/windows
+	rm -rf "${IMAGE_DIR}"/engine/windows
+
+	fowners -R jffnms:apache "${INSTALL_DIR}"
+	fperms -R ug+rw "${INSTALL_DIR}"
+}
+
+pkg_postinst() {
+	elog "${PN} has been partialy installed on your system. However you"
+	elog "still need proceed with final installation and configuration."
+	elog "You can visit https://wiki.gentoo.org/wiki/Jffnms in order"
+	elog "to get detailed information on how to get jffnms up and running."
+}