net-analyzer/sngrep: Version 1.4.7

- Add USE=logo
- EAPI=7
- RESTRICT=test
- Fix setting LDFLAGS

Package-Manager: Portage-2.3.100, Repoman-2.3.22
Closes: https://bugs.gentoo.org/727790
Closes: https://bugs.gentoo.org/709852
Signed-off-by: Jeroen Roovers <jer@gentoo.org>

1 files changed, 46 insertions, 0 deletions

diff --git a/net-analyzer/sngrep/sngrep-1.4.7.ebuild b/net-analyzer/sngrep/sngrep-1.4.7.ebuild
new file mode 100644
index 000000000000..12eaf83d7002
--- /dev/null
+++ b/net-analyzer/sngrep/sngrep-1.4.7.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit autotools
+
+DESCRIPTION="Ncurses SIP Messages flow viewer"
+HOMEPAGE="https://github.com/irontec/sngrep"
+SRC_URI="https://github.com/irontec/sngrep/releases/download/v${PV}/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="eep gnutls ipv6 logo openssl pcre unicode"
+REQUIRED_USE="
+	gnutls? ( !openssl )
+"
+
+DEPEND="
+	net-libs/libpcap
+	sys-libs/ncurses:0=[unicode?]
+	openssl? ( dev-libs/openssl:0= )
+	gnutls? ( net-libs/gnutls )
+"
+RDEPEND="${DEPEND}"
+RESTRICT="test"
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.4.5-tinfo.patch
+	"${FILESDIR}"/${PN}-1.4.7-LDFLAGS.patch
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable eep) \
+		$(use_enable ipv6) \
+		$(use_enable logo) \
+		$(use_enable unicode) \
+		$(use_with gnutls) \
+		$(use_with openssl) \
+		$(use_with pcre)
+}