net-fs/s3ql: moved from sys-fs/s3ql

1 files changed, 55 insertions, 0 deletions

diff --git a/net-fs/s3ql/s3ql-2.11.1.ebuild b/net-fs/s3ql/s3ql-2.11.1.ebuild
new file mode 100644
index 000000000000..cf5f32acae4c
--- /dev/null
+++ b/net-fs/s3ql/s3ql-2.11.1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python3_{3,4} )
+
+inherit distutils-r1
+
+DESCRIPTION="A full-featured file system for online data storage"
+HOMEPAGE="https://bitbucket.org/nikratio/s3ql/"
+SRC_URI="https://www.bitbucket.org/nikratio/s3ql/downloads/${P}.tar.bz2"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="contrib doc test"
+
+RDEPEND=">=dev-db/sqlite-3.7.0:3
+	dev-python/defusedxml[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/apsw-3.7.0[${PYTHON_USEDEP}]
+	>=dev-python/dugong-3.2[${PYTHON_USEDEP}]
+	>=dev-python/llfuse-0.39[${PYTHON_USEDEP}]
+	dev-python/pycrypto[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	sys-fs/fuse"
+DEPEND="${RDEPEND}
+	test? (
+		dev-python/pytest[${PYTHON_USEDEP}]
+		net-misc/rsync[xattr]
+	)"
+
+RESTRICT="test"
+
+python_test() {
+	addwrite /dev/fuse
+	py.test -v tests || die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	if use contrib ; then
+		exeinto /usr/share/doc/${PF}/contrib
+		docompress -x /usr/share/doc/${PF}/contrib
+		doexe contrib/*.{py,sh}
+		doman contrib/*.1
+	fi
+
+	if use doc ; then
+		dodoc doc/manual.pdf
+		dohtml -r doc/html/*
+	fi
+}