net-im/gajim: Version Bump

Gentoo-Bug: https://bugs.gentoo.org/show_bug.cgi?id=608290
Package-Manager: Portage-2.3.6, Repoman-2.3.2
Signed-off-by: Justin Lecher <jlec@gentoo.org>

2 files changed, 120 insertions, 0 deletions

diff --git a/net-im/gajim/Manifest b/net-im/gajim/Manifest
index cfacdd4ba281..67a217d25614 100644
--- a/net-im/gajim/Manifest
+++ b/net-im/gajim/Manifest
@@ -1 +1,2 @@
 DIST gajim-0.16.6.tar.bz2 4564505 SHA256 1357ed178ce497d28fc2d48960b999821e1370f42ffaa4669c1cb803fce778dc SHA512 6c8c2a38429468a1e6f02aae730ff947c649960e8cc672457c1e1733ab2dad6534b1e5ac2e1c0c385e331a6ba817c6e67c1a27443632b9fd43e7ab76ad66c935 WHIRLPOOL c0b3bdd60405123e1d0d004eac1a606dcbf485a8adf500f2c97ede45ebaf727f0c6c29d91066a7172ac459d473d1dc7703537950d8bfd31f1dbac857b734f4cf
+DIST gajim-0.16.8.tar.bz2 4465521 SHA256 46d4887857455b6e104d0478735edb51569bfa384578ffb4f4da81f1649b6a32 SHA512 702917f5b81a5009177ad305a65398c3f8fc95e4666dbfb33ef569a7c2a494a8ea7c48133a1f8000337381b29fc63b917103e05f64686affaaedb8aa155ac0e0 WHIRLPOOL b2bc7e5a31f6b44fcb84316e0f084b950dca171ab8f73ae30b1adb5d01f502a809a6f7a18375e9ea75b8e864e7a6c86e5ec1564a5884b9e7f274a529d1247455
diff --git a/net-im/gajim/gajim-0.16.8.ebuild b/net-im/gajim/gajim-0.16.8.ebuild
new file mode 100644
index 000000000000..ef7a2fe9d3d0
--- /dev/null
+++ b/net-im/gajim/gajim-0.16.8.ebuild
@@ -0,0 +1,119 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE="sqlite,xml"
+
+AUTOTOOLS_AUTORECONF=true
+
+inherit autotools-utils python-r1 versionator
+
+MY_PV=${PV/_/-}
+MY_P="${PN}-${MY_PV}"
+
+DESCRIPTION="Jabber client written in PyGTK"
+HOMEPAGE="http://www.gajim.org/"
+SRC_URI="
+	http://www.gajim.org/downloads/$(get_version_component_range 1-2)/${MY_P}.tar.bz2"
+#	test? ( https://dev.gentoo.org/~jlec/distfiles/${PN}-tests-${PV}.tar.xz )"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~x86-fbsd"
+IUSE="crypt dbus gnome gnome-keyring kde idle jingle libnotify networkmanager nls spell +srv test X xhtml zeroconf"
+
+REQUIRED_USE="
+	${PYTHON_REQUIRED_USE}
+	libnotify? ( dbus )
+	gnome? ( gnome-keyring )
+	zeroconf? ( dbus )"
+
+COMMON_DEPEND="
+	${PYTHON_DEPS}
+	dev-python/pygtk:2[${PYTHON_USEDEP}]
+	x11-libs/gtk+:2"
+DEPEND="${COMMON_DEPEND}
+	>=dev-util/intltool-0.40.1
+	virtual/pkgconfig
+	>=sys-devel/gettext-0.17-r1"
+RDEPEND="${COMMON_DEPEND}
+	dev-python/pyasn1[${PYTHON_USEDEP}]
+	>=dev-python/pyopenssl-0.14[${PYTHON_USEDEP}]
+	>=dev-python/python-nbxmpp-0.5.6[${PYTHON_USEDEP}]
+	crypt? (
+		app-crypt/gnupg
+		dev-python/pycrypto[${PYTHON_USEDEP}]
+		)
+	dbus? (
+		dev-python/dbus-python[${PYTHON_USEDEP}]
+		dev-libs/dbus-glib
+		libnotify? ( dev-python/notify-python[${PYTHON_USEDEP}] )
+		zeroconf? ( net-dns/avahi[dbus,gtk,python,${PYTHON_USEDEP}] )
+		)
+	gnome? (
+		dev-python/libgnome-python[${PYTHON_USEDEP}]
+		dev-python/egg-python[${PYTHON_USEDEP}]
+		)
+	gnome-keyring? ( dev-python/gnome-keyring-python[${PYTHON_USEDEP}] )
+	idle? ( x11-libs/libXScrnSaver )
+	jingle? ( net-libs/farstream:0.1[python,${PYTHON_USEDEP}] )
+	kde? ( kde-apps/kwalletmanager )
+	networkmanager? (
+			dev-python/dbus-python[${PYTHON_USEDEP}]
+			net-misc/networkmanager
+		)
+	spell? ( app-text/gtkspell:2 )
+	srv? (
+		|| (
+			dev-python/libasyncns-python[${PYTHON_USEDEP}]
+			net-dns/bind-tools
+			)
+		)
+	xhtml? ( dev-python/docutils[${PYTHON_USEDEP}] )"
+
+RESTRICT="test"
+
+S="${WORKDIR}"/${MY_P}
+
+src_prepare() {
+	autotools-utils_src_prepare
+	python_copy_sources
+}
+
+src_configure() {
+	configuration() {
+		local myeconfargs=(
+			$(use_enable nls)
+			$(use_with X x)
+			--docdir="/usr/share/doc/${PF}"
+			--libdir="$(python_get_sitedir)"
+			--enable-site-packages
+		)
+		run_in_build_dir autotools-utils_src_configure
+	}
+	python_foreach_impl configuration
+}
+
+src_compile() {
+	compilation() {
+		run_in_build_dir autotools-utils_src_compile
+	}
+	python_foreach_impl compilation
+}
+
+src_test() {
+	testing() {
+		run_in_build_dir ${PYTHON} test/runtests.py --verbose 3 || die
+	}
+	python_foreach_impl testing
+}
+
+src_install() {
+	installation() {
+		run_in_build_dir autotools-utils_src_install
+		python_optimize
+	}
+	python_foreach_impl installation
+}