net-im/mattermost-desktop-bin: add 5.3.0_rc1

Signed-off-by: Viorel Munteanu <ceamac@gentoo.org>

2 files changed, 95 insertions, 0 deletions

diff --git a/net-im/mattermost-desktop-bin/Manifest b/net-im/mattermost-desktop-bin/Manifest
index 5b5c4cdec88e..31841085d59e 100644
--- a/net-im/mattermost-desktop-bin/Manifest
+++ b/net-im/mattermost-desktop-bin/Manifest
@@ -1,2 +1,4 @@
 DIST mattermost-desktop-5.2.2-linux-arm64.tar.gz 116257022 BLAKE2B 42019e849b415870e0f3cda7fd9c0e559945456ac4d06319edf074aecc9ca9bb330aa8547104d4d132f00e237324b6c9bc94dd8e1cd1bc83f50ab50f094a7fc3 SHA512 67f32eff87eae54c4cbfe2ffbec3aca1f6be39836d4e912870809a628888bbe12c2c30a16c7abc1caab0bba77c1f1b97baa01ee10d3f91615b89a57041a4c64a
 DIST mattermost-desktop-5.2.2-linux-x64.tar.gz 115646636 BLAKE2B f3d01c913205dcf2c14cfcfcfc8eba06909c36446a8d6f450270f50328adaf585c5eefa68de212fcc61d012d74b69053790ba9494ee291a90c2b382b530e2e23 SHA512 5ef578c2af8afcd55b75f93904eead8257c0f1e9614de34a13705da2c8ce8f0da2ea57cc62b1fffb12b8effa2a2a98bb200c43a7f43635dc910fa91f7e629f35
+DIST mattermost-desktop-5.3.0-rc.1-linux-arm64.tar.gz 99846118 BLAKE2B a23325ed7046669bc4d888ffb098eee5a3a278c2b4d93e99bfdfe68808fd4334aa354485d0b55e1456df7e48283ace37c647ffcc069a2af4cd88164ed1a4d785 SHA512 655353c24f4598ca80a3c6faf263c9e12d787386428ddc6c78a8ac562171138e2b1f59f8b492d11552c929c2f30a4234c6f12dd467320c13d515cf3a2f4a24ea
+DIST mattermost-desktop-5.3.0-rc.1-linux-x64.tar.gz 99648824 BLAKE2B 109fe211f55186e9f85ecc120f2b118396a0cd307abc6a4e89d2f4889546dd3cb2b1f931d44bded3f68fde6641971f67d8d44bed12c152c842264944003474ac SHA512 69dbfd3820ec19a34c2a7e06e02f2d6004044b4fa3831b5532059e358be31ffab9e7d057da68f4e39d64310c294ca63adc4fe3bb059c8c963fb51c03d52e5eb4
diff --git a/net-im/mattermost-desktop-bin/mattermost-desktop-bin-5.3.0_rc1.ebuild b/net-im/mattermost-desktop-bin/mattermost-desktop-bin-5.3.0_rc1.ebuild
new file mode 100644
index 000000000000..bcf659429aa4
--- /dev/null
+++ b/net-im/mattermost-desktop-bin/mattermost-desktop-bin-5.3.0_rc1.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PN="${PN%-*}"
+MY_PV="${PV/_rc/-rc.}"
+
+inherit desktop xdg
+
+DESCRIPTION="Mattermost Desktop application"
+HOMEPAGE="https://mattermost.com/"
+
+SRC_URI="
+	amd64? ( https://releases.mattermost.com/desktop/${MY_PV}/mattermost-desktop-${MY_PV}-linux-x64.tar.gz )
+	arm64? ( https://releases.mattermost.com/desktop/${MY_PV}/mattermost-desktop-${MY_PV}-linux-arm64.tar.gz )
+"
+
+LICENSE="Apache-2.0 GPL-2+ LGPL-2.1+ MIT"
+SLOT="0"
+# Starting with 5.2.0 upstream dropped x86 for their binary release #879519
+if [[ ${PV} != *rc* ]]; then
+	KEYWORDS="~amd64 ~arm64"
+fi
+
+RDEPEND="
+	>=app-accessibility/at-spi2-core-2.46.0:2[X]
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	dev-libs/wayland
+	media-libs/alsa-lib
+	media-libs/mesa
+	net-print/cups
+	sys-apps/dbus
+	sys-libs/glibc
+	x11-libs/cairo
+	x11-libs/gtk+:3[X]
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXrandr
+	x11-libs/libdrm
+	x11-libs/libxcb
+	x11-libs/libxkbcommon
+	x11-libs/pango
+"
+
+QA_PREBUILT="
+	opt/mattermost-desktop/mattermost-desktop
+	opt/mattermost-desktop/libnode.so
+	opt/mattermost-desktop/libffmpeg.so
+	opt/mattermost-desktop/libGLESv2.so
+	opt/mattermost-desktop/libEGL.so
+	opt/mattermost-desktop/libvk_swiftshader.so
+	opt/mattermost-desktop/libvulkan.so.1
+	opt/mattermost-desktop/resources/*
+"
+
+DOCS=(
+	NOTICE.txt
+)
+
+S="${WORKDIR}"
+
+src_install() {
+	if use amd64; then
+		cd mattermost-desktop-${MY_PV}-linux-x64 || die
+	elif use arm64; then
+		cd mattermost-desktop-${MY_PV}-linux-arm64 || die
+	fi
+	newicon app_icon.png ${MY_PN}.png
+
+	insinto "/opt/${MY_PN}/locales"
+	doins locales/*.pak
+
+	insinto "/opt/${MY_PN}/resources"
+	doins -r resources/*.asar*
+
+	insinto "/opt/${MY_PN}"
+	doins *.pak *.bin *.dat
+	exeinto "/opt/${MY_PN}"
+	doexe *.so *.so.* "${MY_PN}"
+
+	dosym -r "/opt/${MY_PN}/${MY_PN}" "/usr/bin/${MY_PN}"
+
+	make_desktop_entry "${MY_PN}" Mattermost "${MY_PN}"
+
+	einstalldocs
+}