proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 66 insertions, 0 deletions

diff --git a/net-irc/scrollz/scrollz-2.2.1.ebuild b/net-irc/scrollz/scrollz-2.2.1.ebuild
new file mode 100644
index 000000000000..dd2989e25cea
--- /dev/null
+++ b/net-irc/scrollz/scrollz-2.2.1.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=4
+
+inherit eutils toolchain-funcs
+
+MY_P=ScrollZ-${PV}
+
+DESCRIPTION="Advanced IRC client based on ircII"
+HOMEPAGE="http://scrollz.com/"
+SRC_URI="http://www.scrollz.com/download/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="amd64 ppc x86 ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE="gmp gnutls ipv6 socks5 ssl"
+
+REQUIRED_USE="gnutls? ( ssl )"
+
+RDEPEND="sys-libs/ncurses
+	gmp? ( dev-libs/gmp )
+	ssl? (
+		gnutls? ( net-libs/gnutls )
+		!gnutls? ( dev-libs/openssl )
+		)"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-2.2-cppflags.patch
+	epatch "${FILESDIR}"/${PN}-2.2-make-install.patch
+}
+
+src_configure() {
+	local _myssl
+
+	if use ssl; then
+		if use gnutls; then
+			_myssl="--with-ssl"
+		else
+			_myssl="--with-openssl"
+		fi
+	fi
+
+	tc-export CC #397441, ancient autoconf
+	econf \
+		--with-default-server=irc.gentoo.org \
+		$(use_enable socks5) \
+		$(use_enable ipv6) \
+		--enable-regexp \
+		$(use_enable gmp fish) \
+		${_myssl}
+}
+
+src_install() {
+	emake \
+		DESTDIR="${D}" \
+		mandir="${EPREFIX}/usr/share/man/man1" \
+		install
+
+	dodoc ChangeLog* NEWS README* todo
+}