net-irc/kvirc: Version bump (5.0_pre20170601121930).

2 files changed, 139 insertions, 0 deletions

diff --git a/net-irc/kvirc/Manifest b/net-irc/kvirc/Manifest
index 9e8a23a732be..e7920e76c4d0 100644
--- a/net-irc/kvirc/Manifest
+++ b/net-irc/kvirc/Manifest
@@ -1,2 +1,3 @@
 DIST kvirc-5.0_pre20170202154736.tar.gz 6106786 SHA256 a17a214fb24b44d9c799cc85e98ec1a92a50401c3f662587ef355532329293ad SHA512 b2055f6c06426639f87499a8242c97b0dfb7168edfafa3c2a124dfb70799c361d8e5ae14e71605819372e2c66c4c97a18a919423a3ce2f64b276ea20edd02b18 WHIRLPOOL bc8d74142b21a6f80816bef6840d344ce92154a081bf1bd9cc6bdcd2213ebb8313bdc209ecb20e916cf7e97c0ec49f1294f2e04a57fa00eadfbd478fdf417787
 DIST kvirc-5.0_pre20170401092246.tar.gz 6031692 SHA256 d82c621b0b3f5cc2620270a651c2b223b12afc997b8b8d9e2fd2d6f43fcfbfa0 SHA512 735b80422571edcb0b34d14342d7d54d420f4c604abecb86db5a5f42091de4c8927855f81d513de6f7870ed0abb690026f91ab3a7693bf1b873dbda75fbab393 WHIRLPOOL f21b888a7ec39c1af0965b45f8f467df27904f168b44fa36db9c0ab113ae2547328c54c8be0a4bf0ec9cad066f9e8ba0b6c8cc3127205007225fc99860601b8b
+DIST kvirc-5.0_pre20170601121930.tar.gz 6039039 SHA256 47fa486265d3643d43165e85aec0fce9aa7ca187daebaee0a157488e007b1ea0 SHA512 75883a370760924eef13903a49fc304cf67de075765b304453df9afb6455392d455962db6bfb2dc39d64fbe1ba922c2530704071f952c8879b6c83eaac44b90a WHIRLPOOL 513402a0b5f9b444b5021b1694250c4e07ec437f1c9cfeb70fc2e741224682adc50451f708b6fbd890e2d020ccc7af0a56f38f3fdfa8a1f9d049faeb4105230e
diff --git a/net-irc/kvirc/kvirc-5.0_pre20170601121930.ebuild b/net-irc/kvirc/kvirc-5.0_pre20170601121930.ebuild
new file mode 100644
index 000000000000..5e119e5dc07b
--- /dev/null
+++ b/net-irc/kvirc/kvirc-5.0_pre20170601121930.ebuild
@@ -0,0 +1,138 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="5"
+PYTHON_COMPAT=(python2_7)
+
+inherit cmake-utils flag-o-matic multilib python-single-r1
+
+if [[ "${PV}" == "9999" ]]; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/kvirc/KVIrc"
+	KVIRC_GIT_REVISION=""
+	KVIRC_GIT_SOURCES_DATE=""
+else
+	inherit vcs-snapshot
+
+	KVIRC_GIT_REVISION="2c89201e37740afd562333117f00ca53fe871fe3"
+	KVIRC_GIT_SOURCES_DATE="${PV#*_pre}"
+	KVIRC_GIT_SOURCES_DATE="${KVIRC_GIT_SOURCES_DATE:0:4}-${KVIRC_GIT_SOURCES_DATE:4:2}-${KVIRC_GIT_SOURCES_DATE:6:2}"
+fi
+
+DESCRIPTION="Advanced IRC Client"
+HOMEPAGE="http://www.kvirc.net/ https://github.com/kvirc/KVIrc"
+if [[ "${PV}" == "9999" ]]; then
+	SRC_URI=""
+else
+	SRC_URI="https://github.com/kvirc/KVIrc/archive/${KVIRC_GIT_REVISION}.tar.gz -> ${P}.tar.gz"
+fi
+
+LICENSE="kvirc"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE="audiofile +dbus dcc_video debug doc gsm kde +nls oss +perl +phonon profile +python spell +ssl theora webkit"
+REQUIRED_USE="audiofile? ( oss ) python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtmultimedia:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtprintsupport:5
+	dev-qt/qtsql:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	dev-qt/qtxml:5
+	sys-libs/zlib:0=
+	x11-libs/libX11
+	x11-libs/libXScrnSaver
+	audiofile? ( media-libs/audiofile )
+	dbus? ( dev-qt/qtdbus:5 )
+	dcc_video? ( dev-qt/qtmultimedia:5[widgets] )
+	kde? (
+		kde-frameworks/kcoreaddons:5
+		kde-frameworks/ki18n:5
+		kde-frameworks/knotifications:5
+		kde-frameworks/kservice:5
+		kde-frameworks/kwindowsystem:5
+		kde-frameworks/kxmlgui:5
+	)
+	perl? ( dev-lang/perl:0= )
+	phonon? ( media-libs/phonon:0[qt5] )
+	python? ( ${PYTHON_DEPS} )
+	spell? ( app-text/enchant )
+	ssl? ( dev-libs/openssl:0= )
+	theora? (
+		media-libs/libogg
+		media-libs/libtheora
+		media-libs/libvorbis
+	)
+	webkit? ( dev-qt/qtwebkit:5 )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+	kde? ( kde-frameworks/extra-cmake-modules:5 )
+	nls? ( sys-devel/gettext )"
+RDEPEND="${RDEPEND}
+	gsm? ( media-sound/gsm )"
+
+DOCS=(ChangeLog doc/FAQ)
+
+pkg_setup() {
+	if use python; then
+		python-single-r1_pkg_setup
+	fi
+}
+
+src_prepare() {
+	cmake-utils_src_prepare
+
+	if [[ "${PV}" == "9999" ]]; then
+		KVIRC_GIT_REVISION="$(git show -s --format=%H)"
+		KVIRC_GIT_SOURCES_DATE="$(git show -s --format=%cd --date=short)"
+	fi
+	einfo "Setting of revision number to ${KVIRC_GIT_REVISION} ${KVIRC_GIT_SOURCES_DATE}"
+	sed -e "/#define KVI_DEFAULT_FRAME_CAPTION/s/KVI_VERSION/& \" (${KVIRC_GIT_REVISION} ${KVIRC_GIT_SOURCES_DATE})\"/" -i src/kvirc/ui/KviMainWindow.cpp || die "Setting of revision number failed"
+}
+
+src_configure() {
+	append-flags -fno-strict-aliasing
+
+	local libdir="$(get_libdir)"
+	local mycmakeargs=(
+		-DLIB_SUFFIX=${libdir#lib}
+		-DMANUAL_REVISION=${KVIRC_GIT_REVISION}
+		-DMANUAL_SOURCES_DATE=${KVIRC_GIT_SOURCES_DATE//-/}
+		-DWANT_ENV_FLAGS=yes
+		-DWANT_VERBOSE=yes
+
+		-DWANT_CRYPT=yes
+		-DWANT_DCC_VOICE=yes
+		-DWANT_IPC=yes
+		-DWANT_IPV6=yes
+		-DWANT_TRANSPARENCY=yes
+
+		-DWANT_AUDIOFILE=$(usex audiofile)
+		-DWANT_DCC_VIDEO=$(usex dcc_video)
+		-DWANT_DEBUG=$(usex debug)
+		-DWANT_DOXYGEN=$(usex doc)
+		-DWANT_GETTEXT=$(usex nls)
+		-DWANT_GSM=$(usex gsm)
+		-DWANT_KDE=$(usex kde)
+		-DWANT_MEMORY_PROFILE=$(usex profile)
+		-DWANT_OGG_THEORA=$(usex theora)
+		-DWANT_OPENSSL=$(usex ssl)
+		-DWANT_OSS=$(usex oss)
+		-DWANT_PERL=$(usex perl)
+		-DWANT_PHONON=$(usex phonon)
+		-DWANT_PYTHON=$(usex python)
+		-DWANT_QTDBUS=$(usex dbus)
+		-DWANT_QTWEBKIT=$(usex webkit)
+		-DWANT_SPELLCHECKER=$(usex spell)
+
+		# COMPILE_SVG_SUPPORT not used in source code.
+		-DWANT_QTSVG=no
+	)
+
+	cmake-utils_src_configure
+}