net-libs/libqmi: Version bump to 1.22.2

EAPI bump 6->7.
GLIB minimum version 2.36 as per upstream autoconf.
MBIM minimum version 1.18 as per upstream autoconf.
Updated SLOT based on current SONAME.
Test-suite passes.

Closes: https://bugs.gentoo.org/681450
Suggested-By: Mart Raudsepp <leio@gentoo.org>
Signed-Off-By: Tony Vroon <chainsaw@gentoo.org>
Package-Manager: Portage-2.3.62, Repoman-2.3.11

1 files changed, 46 insertions, 0 deletions

diff --git a/net-libs/libqmi/libqmi-1.22.2.ebuild b/net-libs/libqmi/libqmi-1.22.2.ebuild
new file mode 100644
index 000000000000..84afb73ad2d7
--- /dev/null
+++ b/net-libs/libqmi/libqmi-1.22.2.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+inherit multilib
+if [[ ${PV} == "9999" ]] ; then
+	inherit git-r3 autotools
+	EGIT_REPO_URI="https://anongit.freedesktop.org/git/libqmi.git"
+else
+	KEYWORDS="~amd64 ~arm ~arm64 ~mips ~ppc ~ppc64 ~x86"
+	SRC_URI="https://www.freedesktop.org/software/libqmi/${P}.tar.xz"
+fi
+
+DESCRIPTION="Qualcomm MSM (Mobile Station Modem) Interface (QMI) modem protocol library"
+HOMEPAGE="https://cgit.freedesktop.org/libqmi/"
+
+LICENSE="LGPL-2"
+SLOT="0/5.4"	# soname of libqmi-glib.so
+IUSE="doc +mbim static-libs"
+
+RDEPEND=">=dev-libs/glib-2.36
+	virtual/libgudev
+	mbim? ( >=net-libs/libmbim-1.18.0 )"
+DEPEND="${RDEPEND}
+	doc? ( dev-util/gtk-doc )
+	virtual/pkgconfig"
+[[ ${PV} == "9999" ]] && DEPEND+=" dev-util/gtk-doc" #469214
+
+src_prepare() {
+	default
+	[[ -e configure ]] || eautoreconf
+}
+
+src_configure() {
+	econf \
+		--disable-more-warnings \
+		$(use_enable mbim mbim-qmux) \
+		$(use_enable static{-libs,}) \
+		$(use_enable {,gtk-}doc)
+}
+
+src_install() {
+	default
+	use static-libs || rm -f "${ED}/usr/$(get_libdir)/${PN}-glib.la"
+}