net-misc/connman: Version bump to 1.32

Gentoo-bug: 581368
Package-Manager: portage-2.2.28

1 files changed, 73 insertions, 0 deletions

diff --git a/net-misc/connman/connman-1.32.ebuild b/net-misc/connman/connman-1.32.ebuild
new file mode 100644
index 000000000000..d035086a1f61
--- /dev/null
+++ b/net-misc/connman/connman-1.32.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="6"
+inherit systemd
+
+DESCRIPTION="Provides a daemon for managing internet connections"
+HOMEPAGE="https://01.org/connman"
+SRC_URI="mirror://kernel/linux/network/${PN}/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"
+IUSE="bluetooth debug doc examples +ethernet l2tp ofono openvpn openconnect pptp policykit tools vpnc +wifi wispr"
+
+RDEPEND=">=dev-libs/glib-2.16
+	>=sys-apps/dbus-1.2.24
+	>=net-firewall/iptables-1.4.8
+	bluetooth? ( net-wireless/bluez )
+	l2tp? ( net-dialup/xl2tpd )
+	ofono? ( net-misc/ofono )
+	openconnect? ( net-misc/openconnect )
+	openvpn? ( net-misc/openvpn )
+	policykit? ( sys-auth/polkit )
+	pptp? ( net-dialup/pptpclient )
+	vpnc? ( net-misc/vpnc )
+	wifi? ( >=net-wireless/wpa_supplicant-2.0[dbus] )
+	wispr? ( net-libs/gnutls )"
+
+DEPEND="${RDEPEND}
+	>=sys-kernel/linux-headers-2.6.39"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-1.32-execinfo-assumptions.patch"
+	"${FILESDIR}/${PN}-1.31-xtables.patch"
+)
+
+src_configure() {
+	econf \
+		--localstatedir=/var \
+		--enable-client \
+		--enable-datafiles \
+		--enable-loopback=builtin \
+		$(use_enable examples test) \
+		$(use_enable ethernet ethernet builtin) \
+		$(use_enable wifi wifi builtin) \
+		$(use_enable bluetooth bluetooth builtin) \
+		$(use_enable l2tp l2tp builtin) \
+		$(use_enable ofono ofono builtin) \
+		$(use_enable openconnect openconnect builtin) \
+		$(use_enable openvpn openvpn builtin) \
+		$(use_enable policykit polkit builtin) \
+		$(use_enable pptp pptp builtin) \
+		$(use_enable vpnc vpnc builtin) \
+		$(use_enable wispr wispr builtin) \
+		$(use_enable debug) \
+		$(use_enable tools) \
+		--disable-iospm \
+		--disable-hh2serial-gps
+}
+
+src_install() {
+	default
+	dobin client/connmanctl
+
+	if use doc; then
+		dodoc doc/*.txt
+	fi
+	keepdir /var/lib/${PN}
+	newinitd "${FILESDIR}"/${PN}.initd2 ${PN}
+	newconfd "${FILESDIR}"/${PN}.confd ${PN}
+}