net-misc/remmina: bump to 1.4.10

Package-Manager: Portage-3.0.12, Repoman-3.0.2
Signed-off-by: Ben Kohler <bkohler@gentoo.org>

2 files changed, 99 insertions, 0 deletions

diff --git a/net-misc/remmina/Manifest b/net-misc/remmina/Manifest
index ecb7a16d3206..33ac4b91541a 100644
--- a/net-misc/remmina/Manifest
+++ b/net-misc/remmina/Manifest
@@ -1,2 +1,3 @@
+DIST Remmina-v1.4.10.tar.gz 2072202 BLAKE2B 38b6a3cca9b5956a252d4d4433910d46d0d36a2232a2a107b1e556f118f3b1a6d3c02b0bea26a39a52d572c1380dbb5bdac1acd8d6ba07c97b9acc9a64a9142f SHA512 89fed0b0ed17ac1db57a1d9ad33b80f4d17f6cfb4ff7db9b6434d9d4dabf708971e4d93dd573dbf606d1899311e564f159a656223d66bc4a9d7a15a29b5b5963
 DIST Remmina-v1.4.8.tar.gz 1998851 BLAKE2B 80427d06c041d6315fa8fabe90aa8a52ebd2cd1a76ab0e74672f54328d5fa9d0d287e551a5027e5ef60471ce4d934cfe745742058f26e7b93a95e2a1f85dbfd9 SHA512 cf8ea93904a1643f480d7de72bc4154570bcf184150ffc4b3b06699c95f354bc2f4f595c3b00c6c87e9797dc60bcb9993913647b2073f1e85977026f290d81bf
 DIST Remmina-v1.4.9.tar.gz 2033555 BLAKE2B 901e0118f8231a6bf021a0389a1db9462f19527b21954f3deba24e92e3c04d0d323efa3aeb475f0ec915e8cdc4b55cf331ba2010598e8a58567cba0f353b5177 SHA512 21c5141619874a3d90fd1e2ee9ae87dd4ca4b7dc14c0e16f06bca01b38f84db6e7ab178b0f6e9db703bf5d1ddcb17db45553786bb047cf814b1ff67f4aa6139f
diff --git a/net-misc/remmina/remmina-1.4.10.ebuild b/net-misc/remmina/remmina-1.4.10.ebuild
new file mode 100644
index 000000000000..9a2ee2547ae8
--- /dev/null
+++ b/net-misc/remmina/remmina-1.4.10.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake optfeature xdg
+
+MY_P="${PN^}-v${PV}"
+
+DESCRIPTION="A GTK+ RDP, SPICE, VNC, XDMCP and SSH client"
+HOMEPAGE="https://remmina.org/"
+SRC_URI="https://gitlab.com/Remmina/Remmina/-/archive/v${PV}/${MY_P}.tar.gz"
+
+LICENSE="GPL-2+-with-openssl-exception"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="appindicator crypt cups examples gnome-keyring kwallet libressl nls spice ssh rdp telemetry telepathy vnc webkit zeroconf"
+
+DEPEND="
+	dev-libs/glib:2
+	dev-libs/json-glib
+	dev-libs/libsodium:=
+	net-libs/libsoup
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3
+	x11-libs/libX11
+	x11-libs/libxkbfile
+	appindicator? ( dev-libs/libappindicator:3 )
+	crypt? ( dev-libs/libgcrypt:0= )
+	rdp? ( >=net-misc/freerdp-2.0.0_rc4_p1129[X]
+		<net-misc/freerdp-3[X]
+		cups? ( net-print/cups:= ) )
+	gnome-keyring? ( app-crypt/libsecret )
+	kwallet? ( kde-frameworks/kwallet )
+	!libressl? ( dev-libs/openssl:0= )
+	libressl? ( dev-libs/libressl:0= )
+	spice? ( net-misc/spice-gtk[gtk3] )
+	ssh? ( net-libs/libssh:0=[sftp]
+		x11-libs/vte:2.91 )
+	telepathy? ( net-libs/telepathy-glib )
+	vnc? ( net-libs/libvncserver[jpeg] )
+	webkit? ( net-libs/webkit-gtk:4 )
+	zeroconf? ( >=net-dns/avahi-0.8-r2[dbus,gtk] )
+"
+BDEPEND="
+	dev-util/intltool
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+"
+
+RDEPEND="
+	${DEPEND}
+	virtual/freedesktop-icon-theme
+"
+
+DOCS=( AUTHORS CHANGELOG.md README.md THANKS.md )
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	xdg_environment_reset
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_APPINDICATOR=$(usex appindicator)
+		-DWITH_GCRYPT=$(usex crypt)
+		-DWITH_EXAMPLES=$(usex examples)
+		-DWITH_LIBSECRET=$(usex gnome-keyring)
+		-DWITH_KF5WALLET=$(usex kwallet)
+		-DWITH_GETTEXT=$(usex nls)
+		-DWITH_TRANSLATIONS=$(usex nls)
+		-DWITH_FREERDP=$(usex rdp)
+		-DWITH_CUPS=$(usex cups)
+		-DWITH_SPICE=$(usex spice)
+		-DWITH_LIBSSH=$(usex ssh)
+		-DWITH_VTE=$(usex ssh)
+		-DWITH_TELEPATHY=$(usex telepathy)
+		-DWITH_LIBVNCSERVER=$(usex vnc)
+		-DWITH_WWW=$(usex webkit)
+		-DWITH_AVAHI=$(usex zeroconf)
+		-DWITH_NEWS=$(usex telemetry)
+		-DWITH_ICON_CACHE=OFF
+		-DWITH_UPDATE_DESKTOP_DB=OFF
+	)
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	elog "To get additional features, some optional runtime dependencies"
+	elog "may be installed:"
+	elog ""
+	optfeature "encrypted VNC connections" net-libs/libvncserver[gcrypt]
+	optfeature "XDMCP support" x11-base/xorg-server[xephyr]
+}