net-misc/youtube-dl: Version 2020.09.14

Package-Manager: Portage-3.0.6, Repoman-3.0.1
Signed-off-by: Jeroen Roovers <jer@gentoo.org>

2 files changed, 75 insertions, 0 deletions

diff --git a/net-misc/youtube-dl/Manifest b/net-misc/youtube-dl/Manifest
index 36d5caf4b3d2..6c5c2c1fdf30 100644
--- a/net-misc/youtube-dl/Manifest
+++ b/net-misc/youtube-dl/Manifest
@@ -1 +1,2 @@
 DIST youtube-dl-2020.09.06.tar.gz 3182124 BLAKE2B 557fb81812e91c13201044afdb7b119eeb17f022717a2e33c44f76e47591df3036e344e32d75ed5ba55f1b1fce5079213344c06b682f33c043fb764d0f92c5d6 SHA512 866962ab6a3c24b1951232ffb15c9f49c56156d9cbffa3ad265ee905f4b8e63cbc9695acf0a703c945a3d5da4e6cb4cd67add7f2452d54b0f152eb6ed20a0a7a
+DIST youtube-dl-2020.09.14.tar.gz 3187040 BLAKE2B 6fcf9866a3d6b13d40501677584f8c28bc26d198c20ce2e5c17adf34237c4f6373d0b6d2555780546d1b54e40179afc44c7db700f60755c0eae75f0d3e800f33 SHA512 6cc910e8725bb4d394ba45a1a89a6975e672a0a5869ecd41a312ade9127f3b14bf26268728baf575d41595457d157c6ab7179045687ad0a882b1c6e4bf4e166a
diff --git a/net-misc/youtube-dl/youtube-dl-2020.09.14.ebuild b/net-misc/youtube-dl/youtube-dl-2020.09.14.ebuild
new file mode 100644
index 000000000000..27edc068096a
--- /dev/null
+++ b/net-misc/youtube-dl/youtube-dl-2020.09.14.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=(python3_{6,7,8})
+inherit bash-completion-r1 distutils-r1 readme.gentoo-r1
+
+DESCRIPTION="Download videos from YouTube.com (and more sites...)"
+HOMEPAGE="https://github.com/ytdl-org/youtube-dl/"
+SRC_URI="https://youtube-dl.org/downloads/${PV}/${P}.tar.gz"
+LICENSE="public-domain"
+
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x86-solaris"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+RDEPEND="
+	dev-python/pycryptodome[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+"
+DEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/flake8[${PYTHON_USEDEP}]
+	)
+"
+S=${WORKDIR}/${PN}
+
+src_compile() {
+	distutils-r1_src_compile
+}
+
+python_test() {
+	emake offlinetest
+}
+
+python_install_all() {
+	dodoc README.txt
+	doman ${PN}.1
+
+	newbashcomp ${PN}.bash-completion ${PN}
+
+	insinto /usr/share/zsh/site-functions
+	newins ${PN}.zsh _${PN}
+
+	insinto /usr/share/fish/vendor_completions.d
+	doins ${PN}.fish
+
+	distutils-r1_python_install_all
+
+	rm -r "${ED}"/usr/etc || die
+	rm -r "${ED}"/usr/share/doc/youtube_dl || die
+}
+
+pkg_postinst() {
+	elog "${PN}(1) / https://bugs.gentoo.org/355661 /"
+	elog "https://github.com/rg3/${PN}/blob/master/README.md#faq :"
+	elog
+	elog "${PN} works fine on its own on most sites. However, if you want"
+	elog "to convert video/audio, you'll need ffmpeg (media-video/ffmpeg)."
+	elog "On some sites - most notably YouTube - videos can be retrieved in"
+	elog "a higher quality format without sound. ${PN} will detect whether"
+	elog "ffmpeg is present and automatically pick the best option."
+	elog
+	elog "Videos or video formats streamed via RTMP protocol can only be"
+	elog "downloaded when rtmpdump (media-video/rtmpdump) is installed."
+	elog
+	elog "Downloading MMS and RTSP videos requires either mplayer"
+	elog "(media-video/mplayer) or mpv (media-video/mpv) to be installed."
+	elog
+	elog "If you want ${PN} to embed thumbnails from the metadata into the"
+	elog "resulting MP4 files, consider installing media-video/atomicparsley"
+}