net-misc/youtube-dl: Version 2020.03.24

Package-Manager: Portage-2.3.95, Repoman-2.3.21
Signed-off-by: Jeroen Roovers <jer@gentoo.org>

2 files changed, 79 insertions, 0 deletions

diff --git a/net-misc/youtube-dl/Manifest b/net-misc/youtube-dl/Manifest
index 8319e676d7bb..8596db062fc0 100644
--- a/net-misc/youtube-dl/Manifest
+++ b/net-misc/youtube-dl/Manifest
@@ -1 +1,2 @@
 DIST youtube-dl-2020.03.08.tar.gz 3164037 BLAKE2B 1f011657f394d101106fbed32e13e8bac18199db742974fb43b121b2c76324612f62a8e4a7324e4361643b62a5ad9a1937cc068bf3ea949f9411b92563a61bc9 SHA512 09636e3ec526dbcb043cf61ed4dda5c5c00fac2ecd741bf3cb338ca8de72d1395a95a6189bccced140ca1c37eb3f693332e757ff01eb1a25279b100ccdf39b65
+DIST youtube-dl-2020.03.24.tar.gz 3165706 BLAKE2B 817cd8762f496255e58f909ab04f5fec3627918b4d9b58a9ab12c8bd56a12f672067c1dfe0808d76a96bc97fc7bc9a9e661c4f176577c0257f45d5cf6d0c7b92 SHA512 421c0ae412977cdf94d079aa7982360ffdfc4271bb7af27a598adbdb8454c2044e5c44ff3a9f339e9b0989c1264223ca83bba6a9151d01052f8f72c076d9e369
diff --git a/net-misc/youtube-dl/youtube-dl-2020.03.24.ebuild b/net-misc/youtube-dl/youtube-dl-2020.03.24.ebuild
new file mode 100644
index 000000000000..cc4f38a726e5
--- /dev/null
+++ b/net-misc/youtube-dl/youtube-dl-2020.03.24.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=(python3_{6,7,8})
+inherit bash-completion-r1 distutils-r1 readme.gentoo-r1
+
+DESCRIPTION="Download videos from YouTube.com (and more sites...)"
+HOMEPAGE="https://github.com/ytdl-org/youtube-dl/"
+SRC_URI="https://youtube-dl.org/downloads/${PV}/${P}.tar.gz"
+LICENSE="public-domain"
+
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x86-solaris"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+RDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	|| (
+		dev-python/pycryptodome[${PYTHON_USEDEP}]
+		dev-python/pycrypto[${PYTHON_USEDEP}]
+	)
+"
+DEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/flake8[${PYTHON_USEDEP}]
+	)
+"
+S=${WORKDIR}/${PN}
+
+src_compile() {
+	distutils-r1_src_compile
+}
+
+python_test() {
+	emake offlinetest
+}
+
+python_install_all() {
+	dodoc README.txt
+	doman ${PN}.1
+
+	newbashcomp ${PN}.bash-completion ${PN}
+
+	insinto /usr/share/zsh/site-functions
+	newins ${PN}.zsh _${PN}
+
+	insinto /usr/share/fish/vendor_completions.d
+	doins ${PN}.fish
+
+	distutils-r1_python_install_all
+
+	rm -r "${ED}"/usr/etc || die
+	rm -r "${ED}"/usr/share/doc/youtube_dl || die
+}
+
+pkg_postinst() {
+	elog "${PN}(1) / https://bugs.gentoo.org/355661 /"
+	elog "https://github.com/rg3/${PN}/blob/master/README.md#faq :"
+	elog
+	elog "${PN} works fine on its own on most sites. However, if you want"
+	elog "to convert video/audio, you'll need avconf (media-video/libav) or"
+	elog "ffmpeg (media-video/ffmpeg). On some sites - most notably YouTube -"
+	elog "videos can be retrieved in a higher quality format without sound."
+	elog "${PN} will detect whether avconv/ffmpeg is present and"
+	elog "automatically pick the best option."
+	elog
+	elog "Videos or video formats streamed via RTMP protocol can only be"
+	elog "downloaded when rtmpdump (media-video/rtmpdump) is installed."
+	elog
+	elog "Downloading MMS and RTSP videos requires either mplayer"
+	elog "(media-video/mplayer) or mpv (media-video/mpv) to be installed."
+	elog
+	elog "If you want ${PN} to embed thumbnails from the metadata into the"
+	elog "resulting MP4 files, consider installing media-video/atomicparsley"
+}