net-misc/yt-dlp: revbump with youtube-dl compatibility symlink

Some video players and tools/scripts still try to call youtube-dl
and users would sometime create this symlink themselves given it
functions as a drop-in replacement.

This blocks net-misc/youtube-dl but there should be little reason
to have both installed at same time (youtube-dl is likely headed
for last riting), and so not providing a USE.

Signed-off-by: Ionen Wolkens <ionen@gentoo.org>

1 files changed, 46 insertions, 0 deletions

diff --git a/net-misc/yt-dlp/yt-dlp-2021.10.22-r1.ebuild b/net-misc/yt-dlp/yt-dlp-2021.10.22-r1.ebuild
new file mode 100644
index 000000000000..ccda512819f4
--- /dev/null
+++ b/net-misc/yt-dlp/yt-dlp-2021.10.22-r1.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+inherit bash-completion-r1 distutils-r1
+
+DESCRIPTION="youtube-dl fork with additional features and fixes"
+HOMEPAGE="https://github.com/yt-dlp/yt-dlp"
+SRC_URI="mirror://pypi/${P::1}/${PN}/${P}.tar.gz"
+
+LICENSE="Unlicense"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv ~x86"
+
+RDEPEND="
+	dev-python/keyring[${PYTHON_USEDEP}]
+	dev-python/pycryptodome[${PYTHON_USEDEP}]
+	dev-python/websockets[${PYTHON_USEDEP}]
+	media-libs/mutagen[${PYTHON_USEDEP}]
+	media-video/ffmpeg
+	!net-misc/youtube-dl"
+
+distutils_enable_tests pytest
+
+python_test() {
+	epytest -m 'not download'
+}
+
+python_install_all() {
+	dodoc README.md Changelog.md supportedsites.md
+	doman yt-dlp.1
+
+	dobashcomp completions/bash/yt-dlp
+
+	insinto /usr/share/fish/vendor_completions.d
+	doins completions/fish/yt-dlp.fish
+
+	insinto /usr/share/zsh/site-functions
+	doins completions/zsh/_yt-dlp
+
+	rm -r "${ED}"/usr/share/doc/yt_dlp || die
+
+	dosym yt-dlp /usr/bin/youtube-dl # compatibility symlink
+}