net-misc/yt-dlp: EAPI8 and small adjustments

* remove unused readme.gentoo-r1
* public-domain -> Unlicense
* nose -> pytest, lets the eclass handle that dependency
* use upstream markers to skip download tests rather than names
 (no major change, but lets 3 additional tests run)
* remove mkdir workaround, was fixed upstream in 2021.09.01
* install Changelog.md and supportedsites.md, and remove duplicate
  README.txt in favor of README.md (same contents)
* replace some unnecessary new* commands by do*

Signed-off-by: Ionen Wolkens <ionen@gentoo.org>

1 files changed, 17 insertions, 24 deletions

diff --git a/net-misc/yt-dlp/yt-dlp-2021.10.10.ebuild b/net-misc/yt-dlp/yt-dlp-2021.10.10.ebuild
index e8f9a33a5fe9..ed4cc85dbe9e 100644
--- a/net-misc/yt-dlp/yt-dlp-2021.10.10.ebuild
+++ b/net-misc/yt-dlp/yt-dlp-2021.10.10.ebuild
@@ -1,50 +1,43 @@
 # Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
+EAPI=8
 
 PYTHON_COMPAT=( python3_{8..10} )
-inherit bash-completion-r1 distutils-r1 readme.gentoo-r1
+inherit bash-completion-r1 distutils-r1
 
-DESCRIPTION="A youtube-dl fork with additional features and fixes"
+DESCRIPTION="youtube-dl fork with additional features and fixes"
 HOMEPAGE="https://github.com/yt-dlp/yt-dlp"
-SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
-KEYWORDS="~amd64 ~riscv ~x86"
-LICENSE="public-domain"
-SLOT="0"
+SRC_URI="mirror://pypi/${P::1}/${PN}/${P}.tar.gz"
 
-DEPEND="
-	test? ( dev-python/pytest )
-"
+LICENSE="Unlicense"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv ~x86"
 
 RDEPEND="
+	dev-python/keyring[${PYTHON_USEDEP}]
 	dev-python/pycryptodome[${PYTHON_USEDEP}]
-	media-libs/mutagen[${PYTHON_USEDEP}]
 	dev-python/websockets[${PYTHON_USEDEP}]
-	dev-python/keyring[${PYTHON_USEDEP}]
-	media-video/ffmpeg
-"
+	media-libs/mutagen[${PYTHON_USEDEP}]
+	media-video/ffmpeg"
 
-distutils_enable_tests nose
+distutils_enable_tests pytest
 
 python_test() {
-	# make_lazy_extractors.py tries to rename it out, so fails if it does not exists.
-	mkdir ytdlp_plugins
-	epytest -k 'not download'
+	epytest -m 'not download'
 }
 
 python_install_all() {
+	dodoc README.md Changelog.md supportedsites.md
 	doman yt-dlp.1
 
-	newbashcomp completions/bash/yt-dlp yt-dlp
-
-	insinto /usr/share/zsh/site-functions
-	newins completions/zsh/_yt-dlp _yt-dlp
+	dobashcomp completions/bash/yt-dlp
 
 	insinto /usr/share/fish/vendor_completions.d
 	doins completions/fish/yt-dlp.fish
 
-	distutils-r1_python_install_all
+	insinto /usr/share/zsh/site-functions
+	doins completions/zsh/_yt-dlp
 
-	rm -rf "${ED}"/usr/share/doc/yt_dlp || die
+	rm -r "${ED}"/usr/share/doc/yt_dlp || die
 }