net-misc/electrum: Bump to 4.0.5

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 99 insertions, 0 deletions

diff --git a/net-misc/electrum/Manifest b/net-misc/electrum/Manifest
index 0ff14f3d77fc..71564b7b553a 100644
--- a/net-misc/electrum/Manifest
+++ b/net-misc/electrum/Manifest
@@ -1 +1,2 @@
 DIST electrum-4.0.4.gh.tar.gz 4415688 BLAKE2B 1811b3a5534c343b6bc1efccfab822e2550e0b19563837ee69d93006c081acb116b96a2bfe812420cfd7694190d66eb5e5bb01e5d0271262b714a06979ff053e SHA512 1b4fc9f0ac9624ac271ba65989524f902a465ae50465fd7e9f90366a59e17e6938ab0f58cf9ec8e40c10ee99074e1f800cae080d37da60359091be698957ecda
+DIST electrum-4.0.5.gh.tar.gz 4429965 BLAKE2B 1aad8c0407f1dbe085f7cef580785335823fc773296c040a7ce118b0e3edd4a1972ad0712b98754cc548df841fda6df0c854797557c2a2f57a37bd4f3cc2cdb8 SHA512 a0f2eeb57020dc16b568a4d4fce37522f212036455b4e79abf1d44bc20065e896a861bf1a5547fbcae87c2659720d7937c9c0c817e787209c119a06c05549e76
diff --git a/net-misc/electrum/electrum-4.0.5.ebuild b/net-misc/electrum/electrum-4.0.5.ebuild
new file mode 100644
index 000000000000..0ed6a75d3617
--- /dev/null
+++ b/net-misc/electrum/electrum-4.0.5.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+PYTHON_COMPAT=( python3_{6..8} )
+PYTHON_REQ_USE="ncurses?"
+
+inherit desktop distutils-r1 xdg-utils
+
+DESCRIPTION="User friendly Bitcoin client"
+HOMEPAGE="https://electrum.org/"
+SRC_URI="
+	https://github.com/spesmilo/electrum/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="cli ncurses qrcode +qt5"
+REQUIRED_USE="|| ( cli ncurses qt5 )"
+
+RDEPEND="${PYTHON_DEPS}
+	dev-libs/libsecp256k1
+	>=dev-python/aiohttp-socks-0.3[${PYTHON_USEDEP}]
+	=dev-python/aiorpcX-0.18*[${PYTHON_USEDEP}]
+	>=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
+	dev-python/bitstring[${PYTHON_USEDEP}]
+	<dev-python/dnspython-2[${PYTHON_USEDEP}]
+	>=dev-python/ecdsa-0.14[${PYTHON_USEDEP}]
+	dev-python/pbkdf2[${PYTHON_USEDEP}]
+	dev-python/PySocks[${PYTHON_USEDEP}]
+	dev-python/qrcode[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	>=dev-python/protobuf-python-3.12[${PYTHON_USEDEP}]
+	qrcode? ( media-gfx/zbar[v4l] )
+	qt5? (
+		dev-python/PyQt5[gui,widgets,${PYTHON_USEDEP}]
+	)
+	ncurses? ( $(python_gen_impl_dep 'ncurses') )
+	|| (
+		dev-python/cryptography[${PYTHON_USEDEP}]
+		dev-python/pycryptodome[${PYTHON_USEDEP}]
+	)
+"
+BDEPEND="
+	test? (
+		dev-python/cryptography[${PYTHON_USEDEP}]
+		dev-python/pyaes[${PYTHON_USEDEP}]
+		dev-python/pycryptodome[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	eapply "${FILESDIR}/3.1.2-no-user-root.patch"
+	eapply "${FILESDIR}/3.3.2-desktop.patch"
+
+	# Prevent icon from being installed in the wrong location
+	sed -i '/icons_dirname/d' setup.py || die
+
+	# use backwards-compatible cryptodome API
+	sed -i -e 's:Cryptodome:Crypto:' electrum/crypto.py || die
+
+	local bestgui
+	if use qt5; then
+		bestgui=qt
+	elif use ncurses; then
+		bestgui=text
+	else
+		bestgui=stdio
+	fi
+	sed -i 's/^\([[:space:]]*\)\(config_options\['\''cwd'\''\] = .*\)$/\1\2\n\1config_options.setdefault("gui", "'"${bestgui}"'")\n/' ${PN}/${PN} || die
+
+	eapply_user
+
+	xdg_environment_reset
+	distutils-r1_src_prepare
+}
+
+src_install() {
+	doicon -s 128 electrum/gui/icons/${PN}.png
+	dodoc RELEASE-NOTES
+	distutils-r1_src_install
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}