net-p2p/pybitmessage: version bump to 0.4.4

Gentoo-Bug: 526572

1 files changed, 75 insertions, 0 deletions

diff --git a/net-p2p/pybitmessage/pybitmessage-0.4.4.ebuild b/net-p2p/pybitmessage/pybitmessage-0.4.4.ebuild
new file mode 100644
index 000000000000..782c2ced4640
--- /dev/null
+++ b/net-p2p/pybitmessage/pybitmessage-0.4.4.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE="sqlite"
+
+inherit eutils python-r1 gnome2-utils
+
+DESCRIPTION="P2P communications protocol"
+HOMEPAGE="https://bitmessage.org"
+SRC_URI="https://github.com/Bitmessage/PyBitmessage/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="libressl"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="${PYTHON_DEPS}"
+RDEPEND="${DEPEND}
+	!libressl? ( dev-libs/openssl:0[-bindist] )
+	libressl? ( dev-libs/libressl )
+	dev-python/PyQt4[${PYTHON_USEDEP}]"
+
+S=${WORKDIR}/PyBitmessage-${PV}
+
+src_compile() { :; }
+
+src_install () {
+	cat >> "${T}"/${PN}-wrapper <<-EOF || die
+	#!/usr/bin/env python
+	import os
+	import sys
+	sys.path.append("@SITEDIR@")
+	os.chdir("@SITEDIR@")
+	os.execl('@PYTHON@', '@EPYTHON@', '@SITEDIR@/bitmessagemain.py')
+	EOF
+
+	touch src/__init__.py || die
+
+	install_python() {
+		local python_moduleroot=${PN}
+		python_domodule src/*
+		sed \
+			-e "s#@SITEDIR@#$(python_get_sitedir)/${PN}#" \
+			-e "s#@EPYTHON@#${EPYTHON}#" \
+			-e "s#@PYTHON@#${PYTHON}#" \
+			"${T}"/${PN}-wrapper > ${PN} || die
+		python_doscript ${PN}
+	}
+
+	python_foreach_impl install_python
+
+	dodoc README.md debian/changelog
+	doman man/*
+
+	newicon -s 24 desktop/icon24.png ${PN}.png
+	newicon -s scalable desktop/can-icon.svg ${PN}.svg
+	domenu desktop/${PN}.desktop
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}