summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorGilles Dartiguelongue <eva@gentoo.org>2017-08-20 23:54:36 +0200
committerGilles Dartiguelongue <eva@gentoo.org>2017-08-21 00:47:41 +0200
commit7bed5b288edd71eb9a4b761d3d2539383e3d233d (patch)
tree8d93b591c6d48371f94dcd89d01ff4ba46ae8183 /net-voip
parentdev-cpp/gstreamermm: disable gst-bad wrapping as it is experimental (diff)
downloadgentoo-7bed5b288edd71eb9a4b761d3d2539383e3d233d.tar.gz
gentoo-7bed5b288edd71eb9a4b761d3d2539383e3d233d.tar.bz2
gentoo-7bed5b288edd71eb9a4b761d3d2539383e3d233d.zip
net-voip/telepathy-salut: port to unsplit twisted dependencies, bug #605084
Bump to EAPI=6. Fix python-any-r1 usage for unittests. Update homepage. Add missing sqlite:3 dependency. Package-Manager: Portage-2.3.8, Repoman-2.3.3
Diffstat (limited to 'net-voip')
-rw-r--r--net-voip/telepathy-salut/telepathy-salut-0.8.1-r1.ebuild77
1 files changed, 77 insertions, 0 deletions
diff --git a/net-voip/telepathy-salut/telepathy-salut-0.8.1-r1.ebuild b/net-voip/telepathy-salut/telepathy-salut-0.8.1-r1.ebuild
new file mode 100644
index 00000000000..f5766fe7ad3
--- /dev/null
+++ b/net-voip/telepathy-salut/telepathy-salut-0.8.1-r1.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 )
+
+inherit python-any-r1
+
+DESCRIPTION="A link-local XMPP connection manager for Telepathy"
+HOMEPAGE="https://telepathy.freedesktop.org/"
+SRC_URI="https://telepathy.freedesktop.org/releases/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-linux"
+IUSE="gnutls test"
+
+RDEPEND="
+ >=dev-libs/dbus-glib-0.61
+ dev-libs/libxml2
+ >=dev-libs/glib-2.28:2
+ >=sys-apps/dbus-1.1.0
+ >=net-libs/telepathy-glib-0.17.1
+ >=net-dns/avahi-0.6.22[dbus]
+ net-libs/libsoup:2.4
+ sys-apps/util-linux
+ dev-db/sqlite:3
+ gnutls? ( >=net-libs/gnutls-2.10.2 )
+ !gnutls? ( >=dev-libs/openssl-0.9.8g:0[-bindist] )
+"
+DEPEND="${RDEPEND}
+ ${PYTHON_DEPS}
+ dev-libs/libxslt
+ virtual/pkgconfig
+ test? (
+ >=dev-libs/check-0.9.4
+ net-libs/libgsasl
+ || (
+ $(python_gen_any_dep 'dev-python/twisted[${PYTHON_USEDEP}]')
+ $(python_gen_any_dep 'dev-python/twisted-words[${PYTHON_USEDEP}]')
+ )
+ )
+"
+# FIXME: needs xmppstream python module
+# >=net-dns/avahi-0.6.22[python]
+
+PATCHES=(
+ # Fix uninitialized variable, upstream bug #37701
+ "${FILESDIR}"/${PN}-0.5.0-uninitialized.patch
+)
+
+python_check_deps() {
+ use test \
+ && { has_version "dev-python/twisted[${PYTHON_USEDEP}]" \
+ || has_version "dev-python/twisted-words[${PYTHON_USEDEP}]"; }
+}
+
+pkg_setup() {
+ python-any-r1_pkg_setup
+}
+
+src_configure() {
+ econf \
+ --disable-coding-style-checks \
+ --disable-plugins \
+ --disable-Werror \
+ --disable-static \
+ --disable-avahi-tests \
+ --docdir=/usr/share/doc/${PF} \
+ --with-tls=$(usex gnutls gnutls openssl)
+ #$(use_enable test avahi-tests)
+}
+
+src_install() {
+ MAKEOPTS+=" -j1" default # bug 413581
+ find "${D}" -name '*.la' -delete || die
+}