net-vpn/networkmanager-l2tp: use correct ppp plugin path

By default /usr/lib64/pppd/2.4.7/ path used. This will use right path from portage.

Bug: https://bugs.gentoo.org/722718
Closes: https://github.com/gentoo/gentoo/pull/20926
Signed-off-by: Sam James <sam@gentoo.org>

1 files changed, 61 insertions, 0 deletions

diff --git a/net-vpn/networkmanager-l2tp/networkmanager-l2tp-1.8.2-r1.ebuild b/net-vpn/networkmanager-l2tp/networkmanager-l2tp-1.8.2-r1.ebuild
new file mode 100644
index 000000000000..0db9addd3960
--- /dev/null
+++ b/net-vpn/networkmanager-l2tp/networkmanager-l2tp-1.8.2-r1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_PN="NetworkManager-l2tp"
+MY_P="${MY_PN}-${PV}"
+
+inherit gnome.org autotools
+
+DESCRIPTION="NetworkManager L2TP plugin"
+HOMEPAGE="https://github.com/nm-l2tp/network-manager-l2tp"
+SRC_URI="https://github.com/nm-l2tp/${MY_PN}/releases/download/${PV}/${MY_P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="gnome static-libs"
+
+RDEPEND="
+	>=net-misc/networkmanager-1.2[ppp]
+	dev-libs/dbus-glib
+	net-dialup/ppp:=[eap-tls]
+	net-dialup/xl2tpd
+	>=dev-libs/glib-2.32
+	|| (
+		net-vpn/strongswan
+		net-vpn/libreswan
+	)
+	gnome? (
+		x11-libs/gtk+:3
+		app-crypt/libsecret
+		gnome-extra/nm-applet
+	)"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	sys-devel/gettext
+	dev-util/intltool
+	virtual/pkgconfig"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	eautoreconf
+	eapply_user
+}
+
+src_configure() {
+	local PPPD_VER=$(best_version net-dialup/ppp)
+	PPPD_VER=${PPPD_VER#*/*-} # reduce it to ${PV}-${PR}
+	PPPD_VER=${PPPD_VER%%[_-]*} # main version without beta/pre/patch/revision
+
+	local myeconfargs=(
+		--localstatedir=/var
+		--with-pppd-plugin-dir=/usr/$(get_libdir)/pppd/${PPPD_VER}
+		$(use_with gnome)
+		$(use_enable static-libs static)
+	)
+
+	econf "${myeconfargs[@]}"
+}