sci-biology/bcftools: Version bump to 1.9

Closes: https://bugs.gentoo.org/647714
Signed-off-by: David Seifert <soap@gentoo.org>
Package-Manager: Portage-2.3.50, Repoman-2.3.11

1 files changed, 47 insertions, 0 deletions

diff --git a/sci-biology/bcftools/bcftools-1.9.ebuild b/sci-biology/bcftools/bcftools-1.9.ebuild
new file mode 100644
index 000000000000..53e47bc01a81
--- /dev/null
+++ b/sci-biology/bcftools/bcftools-1.9.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit python-single-r1
+
+DESCRIPTION="Utilities for variant calling and manipulating VCF and BCF files"
+HOMEPAGE="http://www.htslib.org"
+SRC_URI="https://github.com/samtools/${PN}/releases/download/${PV}/${P}.tar.bz2"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	dev-lang/perl
+	=sci-libs/htslib-${PV}*:=
+	sys-libs/zlib:=
+	${PYTHON_DEPS}"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.5-buildsystem.patch
+	"${FILESDIR}"/${PN}-1.9-fix-shebangs.patch
+)
+
+src_prepare() {
+	default
+
+	python_fix_shebang misc/{guess-ploidy,plot-roh}.py
+
+	# remove bundled htslib
+	rm -r htslib-* || die
+}
+
+src_configure() {
+	econf \
+		--disable-bcftools-plugins \
+		--disable-libgsl \
+		--disable-configure-htslib \
+		--with-htslib=system
+}