summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorTed Tanberry <ted.tanberry@gmail.com>2015-10-10 21:07:16 +0200
committerJustin Lecher <jlec@gentoo.org>2015-10-14 14:47:58 +0200
commit5ca4d1505a37f273d7eaee41f89b676381e6305e (patch)
treeec9814e8b3d83ea364036e064d472c3d52449ec2 /sci-biology
parentsci-biology/bowtie: version bump, SLOT major version (diff)
downloadgentoo-5ca4d1505a37f273d7eaee41f89b676381e6305e.tar.gz
gentoo-5ca4d1505a37f273d7eaee41f89b676381e6305e.tar.bz2
gentoo-5ca4d1505a37f273d7eaee41f89b676381e6305e.zip
sci-biology/bowtie: Add bowtie2 in SLOT=2
Diffstat (limited to 'sci-biology')
-rw-r--r--sci-biology/bowtie/bowtie-2.2.6.ebuild54
1 files changed, 54 insertions, 0 deletions
diff --git a/sci-biology/bowtie/bowtie-2.2.6.ebuild b/sci-biology/bowtie/bowtie-2.2.6.ebuild
new file mode 100644
index 00000000000..50aca7e60d0
--- /dev/null
+++ b/sci-biology/bowtie/bowtie-2.2.6.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit eutils toolchain-funcs
+
+DESCRIPTION="Popular short read aligner for Next-generation sequencing data, allowing for gaps"
+HOMEPAGE="http://bowtie-bio.sourceforge.net/bowtie2/"
+SRC_URI="mirror://sourceforge/project/${PN}-bio/${PN}2/${PV}/${PN}2-${PV}-source.zip"
+
+LICENSE="GPL-3"
+SLOT="2"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="examples cpu_flags_x86_sse2 tbb"
+REQUIRED_USE="cpu_flags_x86_sse2"
+
+RDEPEND="dev-lang/perl"
+DEPEND="${RDEPEND}
+ app-arch/unzip
+ tbb? ( dev-cpp/tbb )"
+
+S="${WORKDIR}/${PN}2-${PV}"
+
+DOCS=( AUTHORS NEWS TUTORIAL )
+HTML_DOCS=( doc/{manual.html,style.css} )
+
+src_compile() {
+ emake \
+ CC="$(tc-getCC)" \
+ CPP="$(tc-getCXX)" \
+ CFLAGS="" \
+ CXXFLAGS="" \
+ EXTRA_FLAGS="${LDFLAGS}" \
+ RELEASE_FLAGS="${CXXFLAGS} -msse2" \
+ WITH_TBB="$(usex tbb 1 0)"
+}
+
+src_install() {
+ dobin ${PN}2 ${PN}2-*
+
+ exeinto /usr/libexec/${PN}2
+ doexe scripts/*
+
+ newman MANUAL ${PN}2.1
+ einstalldocs
+
+ if use examples; then
+ insinto /usr/share/${PN}2
+ doins -r example
+ fi
+}