sci-electronics/qelectrotech: version bump 0.61

Closes: https://bugs.gentoo.org/660996
Signed-off-by: Michael Palimaka <kensington@gentoo.org>
Package-Manager: Portage-2.3.49, Repoman-2.3.11

1 files changed, 64 insertions, 0 deletions

diff --git a/sci-electronics/qelectrotech/qelectrotech-0.61.ebuild b/sci-electronics/qelectrotech/qelectrotech-0.61.ebuild
new file mode 100644
index 000000000000..65c80501b9a6
--- /dev/null
+++ b/sci-electronics/qelectrotech/qelectrotech-0.61.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit gnome2-utils qmake-utils xdg-utils
+
+MY_P=${PN}-${PV%0}-src
+
+DESCRIPTION="Qt5 application to design electric diagrams"
+HOMEPAGE="https://qelectrotech.org/"
+SRC_URI="https://download.tuxfamily.org/qet/tags/20180823/${MY_P}.tar.gz"
+
+LICENSE="CC-BY-3.0 GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc"
+
+RDEPEND="
+	dev-qt/qtconcurrent:5
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtprintsupport:5
+	dev-qt/qtsql:5[sqlite]
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen )
+"
+
+S=${WORKDIR}/${MY_P}
+
+DOCS=( CREDIT ChangeLog README )
+PATCHES=( "${FILESDIR}/${PN}-0.3-fix-paths.patch" )
+
+src_configure() {
+	eqmake5 ${PN}.pro
+}
+
+src_install() {
+	emake INSTALL_ROOT="${D}" install
+
+	einstalldocs
+
+	if use doc; then
+		doxygen Doxyfile || die
+		dodoc -r doc/html
+	fi
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+	gnome2_icon_cache_update
+}